■ＰＢ－ＬＯＧＩＣ■

　著作制作…………よなぷー
　制作年月日………２０１６年１０月１日
　対応機種…………ＰＢ－１００／１１０／１２０用ゲームプログラム
　使用メモリ………６９４ステップ
　※「ク」はクラブ、「ス」はスペード、「ハ」はハートの記号です。
　※「●」はスペース一個です。
　※「○」はＥＸＴモードの［ＳＨＩＦＴ］［Ａ］です。
　※「⊂」は［ＡＮＳ］の下の［Ｅ］です。


P0

9 PRINT CSR0;T$(B);B;:IF KEY="W";B=B-SGNB

20 IF KEY="A";A=A-SGNA

30 IF KEY="D";A=A+SGN(6-A

40 IF KEY="X";B=B+SGN(6-B

50 PRINT CSRA;"_";:IF KEY="-";GOSUB #1

60 IF KEY="*";GOSUB #2

70 IF KEY="6";$=M$(B):GOSUB #4

80 IF KEY≠"5" THEN 9

90 FOR B=0 TO 6:PRINT:PRINT B;:FOR A=0 TO 6:GOSUB #6:IF E$="×";GOSUB #3

100 PRINT ".";:NEXT A:IF T$(B)≠M$(B);PRINT "OUT";:A=0:B=0:END

110 NEXT B:A=0:B=0:$="◆NICE-CLEAR◆":FOR C=6 TO 11:FOR D=C TO 11

120 PRINT CSR11-D;MID(12-C,1);CSRD;MID(C+1,1);:NEXT D:NEXT C


P1

10 GOSUB #6:IF E$="□";E$="×":GOTO #5

20 IF E$="×";E$="■":GOTO #5

30 GOTO #3


P2

10 E=0:FOR C=0 TO 6:$=M$(C):E$=E$+MID(A+1,1):NEXT C:$=E$:GOTO #4


P3

10 E$="□":GOTO #5


P4

10 F=0:G=1⊂3:H=0:FOR C=1 TO 7:IF MID(C,1)="□";H=H+1

20 IF MID(C,1)="■";IF H≠0;F=F+H*G:H=0:G=G/10

30 NEXT C:IF H≠0;F=F+H*G

40 PRINT CSR7;F:RETURN


P5

10 $="."+$+".":$=MID(1,A+1)+E$+MID(A+3):T$(B)=MID(2,7):RETURN


P6

10 $=T$(B):E$=MID(A+1,1):RETURN


P9

9 PRINT "●●PB-LOGIC":VAC:$="□■":E$="□□□□□□□":FOR C=0 TO 6:FOR D=0 TO 6

20 M$(C)=M$(C)+MID(RAN#+1.4,1):NEXT D:T$(C)=E$:NEXT C:GOTO #0