■ＦＩＧＨＴＳ■

　著作制作…………よなぷー
　制作年月日………２０１８年１１月２４日
　対応機種…………ＰＢ－１００／１１０／１２０用ゲームプログラム
　使用メモリ………１５６８ステップ
　※「ク」はクラブ、「ス」はスペード、「ハ」はハートの記号です。
　※「●」はスペース一個です。
　※「○」はＥＸＴモードの［ＳＨＩＦＴ］［Ａ］です。
　※「⊂」は［ＡＮＳ］の下の［Ｅ］です。
　※Ｐ２の５４行は『”』二つの間に『’』が挟まれています。


P0

4 GOTO 68

8 GOSUB #3:B=INT(RAN#*5-1:IF 0>B;X=0

12 IF G=H;G=G-SGN(5.5-G:C=0:D=0:GOSUB #7:GOTO 8

16 W=1:K=0:A=G:P=H:T=SGN(P-A:IF C≠0;GOSUB #2:GOTO 44

20 R=0:IF KEY="Q";R=T

24 IF KEY="W";R=-T

28 IF R=1;W=0

32 IF 0>R;GOSUB #1

36 IF KEY="-";Y=I:GOSUB #2:GOTO 44

40 IF KEY="6";Y=J:GOSUB #2

44 IF B=9 THEN 72

48 X=1:K=1:A=H:P=G:T=SGN(P-A:IF D≠0;GOSUB #2:GOTO 8

52 IF B≧2;GOSUB #1

56 IF RAN#*SGNB>.7;D=0:Z=U(RAN#*2):GOSUB #2

60 IF B≠9 THEN 8

64 GOTO 72

68 PRINT "●●●FIGHTS","HI";L,"BY●";O$:F=0:$="%≠+゜○o_●"

72 F=F+1:PRINT CSR4;"ST";F;:I=INT(RAN#*10+1:U=INT(RAN#*10+1

76 J=INT(RAN#*10+1:IF I=J THEN 76

80 V=INT(RAN#*10+1:IF U=V THEN 80

84 G=3:H=8:C=0:D=0:GOSUB #9:GOTO 8


P1

10 A=A+T:PRINT CSRA;"○";CSRA+T;"-";:G(K)=A:IF P≠A;IF P≠A+T;RETURN

20 E=1:GOTO #6


P2

1 IF K=1 THEN 6

3 IF C=0;M=T:IF FRAC SQR Y=0;C=A

4 T=M:C=C+T:S=ABS C:Q=A+T:GOTO Y*9

6 IF D=0;N=T:IF FRAC SQR Z=0;D=A

7 T=N:D=D+T:S=ABS D:Q=A+T:IF T≠0 THEN Z*9

8 RETURN

9 E=2:GOTO #5

18 PRINT CSRA;"z";:R=COS π:IF S=1;RETURN

19 PRINT CSRQ;"■";CSRQ+T;"■";:IF P≠Q;IF P≠Q+T THEN #8

20 E=1:GOTO #6

27 FOR R=A TO P+T STEP T:PRINT CSRR;"μ";:NEXT R:IF S=1;G(K)=R-T:GOTO #7

28 PRINT CSRA-T;"÷";:GOSUB #8:T=-T:E=1:IF P=A+T THEN #6

29 RETURN

36 E=3:C(K)=S+T*SGN S:GOTO #5

45 PRINT CSRQ;"&";:IF S=1;G(K)=Q:RETURN

46 PRINT CSRQ;"↑";:E=3:IF Q=P THEN #6

47 GOTO #8

54 IF S=1;M(K)=P:PRINT CSRP;"'";:RETURN

55 PRINT CSRM(K);"↓";:E=1:T=SGN(P-A:IF P=M(K) THEN #6

56 GOTO #8

63 PRINT CSRA;"Y";:E=2:IF S≦2;RETURN

64 FOR R=0 TO 2:IF ABS(A+T-5.5≦5;A=A+T

65 PRINT CSRA;"\";:IF A=P;GOSUB #6:R=2

66 NEXT R:G(K)=A:GOTO #8

72 FOR R=4 TO 8:PRINT CSRA;MID(R,COS 0);:NEXT R:E=1

73 A=ABS(11-A:FOR R=1 TO 5:PRINT CSRA;MID(9-R,COS 0);:NEXT R

74 G(K)=A:GOSUB #3:IF A=P THEN #6

75 GOTO #8

81 E=1:GOSUB #5:S=C(K):IF S≠0;S=S+T:C(K)=S:GOTO #5

82 RETURN

90 PRINT CSRA;"△";:E=COS 0:IF S=1;RETURN

91 FOR S=1 TO 3:R=2*S*T+A:IF ABS(R-5≦5;PRINT CSRR;"V";:IF R=P;GOSUB #6

92 NEXT S:GOTO #8


P3

10 PRINT CSR0;"_●●●●●●●●●●_";CSRG;"Ω";CSRH;"ス";:RETURN


P5

10 PRINT CSRS;MID(E,1);:R=COS π:IF S=P;GOSUB #6

20 IF S≧10 THEN #8

30 RETURN


P6

10 IF W(1-K)=0;PRINT CSRP;"□";:R=COS π:GOTO #8

20 FOR R=1 TO E:PRINT CSRP;"*";:P=P+T*SGN FRAC(P/11

30 NEXT R:G(1-K)=P:B=0:C=0:D=0:GOTO #7


P7

10 IF ABS(H-5.5>5;PRINT CSR4;"WIN!";:B=9:GOTO #9

20 IF ABS(G-5.5≦5;RETURN

30 GOSUB #3:PRINT CSR4;"LOSE";:GOSUB #9:F=F-1

40 PRINT "SC";F;:IF F≧L;L=F:STOP:PRINT "HI!":INPUT "NAME",O$

50 IF F≧50;PRINT "GOD!";


P8

10 C(K)=0:RETURN


P9

10 FOR R=0 TO 150:NEXT R:PRINT:RETURN