■ＰＢ　ＤＲＩＦＴ■

　著作制作…………よなぷー
　制作年月日………２０１９年２月９日
　対応機種…………ＰＢ－１００／１１０／１２０用ゲームプログラム
　使用メモリ………プログラム＝１４２４ステップ、ＤＥＦＭ１８＝１４４ステップ
　※「ク」はクラブ、「ス」はスペード、「ハ」はハートの記号です。
　※「●」はスペース一個です。
　※「○」はＥＸＴモードの［ＳＨＩＦＴ］［Ａ］です。
　※「⊂」は［ＡＮＳ］の下の［Ｅ］です。


P0

1 GOSUB #1

2 IF INT E≧R THEN 60

3 P$=MID(E,1):B=3-VAL(P$):P$=MID(E+1,1):Y=2+SGN(3-VAL(P$)

4 PRINT CSR0;H$(B+3);S;"●";CSR7;MID(Y,1);CSRX;U$(D+1);:G=G+1

5 IF KEY="+";D=SGN B

6 IF D=0;X=X+B*S/450:GOTO 9

7 S=S-20:IF Q=6;PRINT CSRX;"!";:S=0:Q=0:D=0

8 Q=Q+1:IF KEY≠"+";Q=0:D=0

9 IF KEY="Q";X=X-1

20 IF KEY="-";X=X+1

25 IF KEY="W";X=X-1.5:S=S-45

30 IF KEY="6";X=X+1.5:S=S-45

35 S=S+15:T=1+SGN INT(X/7:IF T≠1;X=3*T:PRINT CSRX;"*";:G=G+10:S=0

40 IF S>293;S=293

45 IF S≦0;S=0:PRINT CSR10;"●●";

50 A=A+S/293:IF A≧4;A=0:E=E+1:GOTO 2

55 GOTO 4

60 PRINT CSR2;"■FINISH■";:GOSUB #7:PRINT "C";C;"TIME";G;

65 IF G>Z(C);END

70 GOSUB #7:PRINT "RecordUpdate";:GOSUB #7:Z(C)=G

75 INPUT "NAME",$:IF LEN($)>3 THEN 75

80 Z$(C+9)=$:IF C≦8;END

85 $="-All●Clear!-":GOSUB #2:$="-Splendid!!-":GOSUB #2

90 $="-YouAreNo.1-":GOSUB #2:PRINT "---GREAT!---";


P1

1 P=0:FOR F=1 TO 8:IF 999>Z(F);P=P+1

2 NEXT F:Z=INT(P/8

3 PRINT "CourseSelect";:GOSUB #8

4 PRINT:PRINT "C";C;Z(C);":";Z$(C+9);

5 IF KEY="Q";C=C-SGN(C-1:GOTO 4

6 IF KEY="-";C=C+SGN(8+Z-C:GOTO 4

7 IF KEY≠"+" THEN 5

8 GOSUB 9+C:$="→↑←"+$+"33":R=LEN($):D=0:E=4:Q=0:G=0:S=0:X=3

9 PRINT:FOR P=3 TO 0 STEP -1:PRINT "]□･△･□[";P;:GOSUB #8:NEXT P:RETURN

10 $="345654345654345654":RETURN

11 $="3210123456543210012":RETURN

12 $="3321234543101356533221100":RETURN

13 $="2103313566431134532001356":RETURN

14 $="45321345642001234566300":RETURN

15 $="456665432100012":RETURN

16 $="3201320145664232100231000":RETURN

17 $="243100132466642001231001":RETURN

18 $="2000134664666543100045666":RETURN


P2

10 FOR R=0 TO 11:FOR P=11 TO R STEP -1:PRINT CSRP;"■";CSRP+COSπ;"●";

20 NEXT P:PRINT CSRR;"*";CSRCOSπ;MID(1,R+1);:NEXT R:GOTO #7


P7

10 FOR F=0 TO 400:NEXT F:PRINT:RETURN


P8

10 FOR F=0 TO 140:NEXT F:PRINT:RETURN


P9

10 $="[[PB●DRIFT]]":GOSUB #2:H$="II]]□･[":I$="I]]□･●["

20 J$="I]□･●･[":K$="]□･●･□[":L$="]･●･□[I":M$="]●･□[[I"

30 N$="]･□[[II":FOR F=1 TO 9:Z(F)=999:Z$(F+9)="P.B"

40 NEXT F:U$="≧":V$="△":W$="≦":C=1:GOTO #0