■ＰＡＮＡＤＵ■

　著作制作…………よなぷー
　制作年月日………２０１９年９月２６日
　対応機種…………ＰＢ－１００／１１０／１２０用ゲームプログラム
　使用メモリ………１５６８ステップ
　※「ク」はクラブ、「ス」はスペード、「ハ」はハートの記号です。
　※「●」はスペース一個です。
　※「○」はＥＸＴモードの［ＳＨＩＦＴ］［Ａ］です。
　※「⊂」は［ＡＮＳ］の下の［Ｅ］です。


P0

1 IF N≧19;PRINT:PRINT "#HAPPY●END!#";:END

2 GOSUB #6:U=0:W=0:FOR K=-2 TO 4:X=E+K:GOSUB #8:NEXT K

3 U=0:PRINT CSR0;W$;D;CSRP;"$";CSR3;"ス";:GOSUB #5:IF V=3 THEN 9

4 IF V=1;X=E-3:U=-3:GOSUB #8

5 IF V=2;X=E+5:U=-1:GOSUB #8

6 P=P-O*(1+SGN U:IF ABS(P-3>3;O=-O:P=3*(O+1

7 IF P=3;Q=N+INT(RAN#*3:GOSUB #4:P=P-O

8 GOTO 3

9 $=W$:W$=MID(4,1):IF W$="o";GOSUB #3:IF Z≧3;PRINT "NEXT":Z=0:N=N+1

20 IF W$≠"□" THEN 1

30 PRINT:PRINT "INN";:GOSUB #2:GOSUB #1:D=M:K=J↑2+8

40 PRINT "+WPN/G";K;:GOSUB #2:IF K>G THEN 2

50 PRINT "GET!";:G=G-K:J=J+1:GOSUB #2:GOTO 2


P1

10 M=H*A+8:IF D≧M;D=M

20 RETURN


P2

10 IF F≧H↑2;PRINT CSR0;"LV↑";:H=H+1:F=0

20 FOR M=0 TO 120:NEXT M:PRINT:RETURN


P3

1 $="■■HGG$":W$="■":FOR K=0 TO 4:W$=W$+MID(RAN#*6+1,1):NEXT K

5 W$=W$+"Σ":L=0

9 PRINT CSR0;W$;D;CSRL;"ス";:GOSUB #5:IF V≠2 THEN 9

20 $=W$:I$=MID(L+2,1):IF I$="H";D=D+20:GOSUB #1

30 IF I$="G";G=G+N↑2

40 IF I$="$";Q=N+2:GOSUB #4

50 IF L=5;U=π:Q=N+4:GOSUB #4:Z=Z+1:E=INT(RAN#*94+4:RETURN

60 L=L+1:GOTO 9


P4

1 $="scuyrewmnzgμπ÷△◆クΩ@%\Σ":T$=MID(Q,1):R=Q↑2+N*2:IF U=π;R=R*3

2 Y=1+INT(3*FRAC(J/3:X=0:B=0:K=3:S=8

3 C=INT(RAN#*4-1:IF R≦0;G=G+Q:F=F+Q:GOSUB #2:GOTO #6

4 PRINT:PRINT CSRK;"ス";CSRS;T$;:GOSUB 40:GOSUB #5:GOSUB V*5+9

5 IF C≧2;GOSUB 60

6 IF C≦1;IF S+C>K;IF S+C≦11;S=S+C

7 GOTO 3

8 B=B+1:IF B≦11;PRINT CSRB;"≠";:IF B=S;R=R-J*(10-A:GOTO 75

9 RETURN

14 K=K-SGN K:RETURN

19 K=K+SGN(S-K-1:RETURN

24 FOR I=1 TO Y:IF K+I≦S;PRINT CSRK+I;"-";

25 IF K+I=S;R=R-J*A:GOSUB 75

26 NEXT I:RETURN

29 IF X=0;B=K:X=Y

30 RETURN

40 IF X=0;RETURN

45 GOSUB 8:IF X≧1;GOSUB 8:IF X=2;GOSUB 8

50 IF B≧11 THEN 80

55 RETURN

60 M=INT(7*FRAC(Q/7:FOR I=S-1 TO S-M STEP -1:IF I≧K;PRINT CSRI;"←";

65 IF I=K;PRINT CSRK;"*";:D=D-Q:IF D≦0;G=INT(G/2:END

70 NEXT I:RETURN

75 PRINT CSRS;"*";:S=S+SGN(11-S:C=0

80 B=0:X=0:RETURN


P5

10 V=0:IF KEY="Q";V=1

20 IF KEY="W";V=2

30 IF KEY="-";V=3

40 IF KEY="6";V=4

50 IF KEY≠"5";RETURN

60 GOSUB #1:PRINT:PRINT H;"L:T";A,D;"H/M";M,J;"W:F";N

70 PRINT Z;"K:G";G:RETURN


P6

10 $="o□I_":RETURN


P7

10 $=W$:IF MID(U+6,1)="#";RETURN

20 IF U=-3;$=I$+$:W$=MID(1,7):E=E-1

30 IF U=-1;$=$+I$:W$=MID(2):E=E+1

40 GOTO #6


P8

10 Y=INT(10*FRAC(1⊂6*LN(X*N:IF Y≧4;Y=3

20 I$=MID(Y+1,1):IF X≦4;I$="#"

30 IF X≧99;I$="#"

40 IF 0>U THEN #7

50 W$=W$+I$:RETURN


P9

9 PRINT "●≦-PANADU-≧":VAC:INPUT "M(1-9)W",A:IF ABS(A-5≧5 THEN 9

20 N=1:E=4:O=1:H=1:D=9:J=1:GOTO #0