Moonlit_Castle_ver11

10 '=MOONLIT CASTLE= VER.1.1 BY YONAPUU,2023-2025

20 GOTO 1130

30 'ﾒｲﾛ ｺｳﾁｸ

40 Y=0:IF X<1 THEN 90

50 E=FRAC(1E6*LN(H*X)):IF E>.7 THEN Y=1:IF E>.95 THEN Y=2

60 IF X=D THEN Y=3

70 IF X=F THEN Y=4

80 IF X>=11 AND X<=99 AND FRAC(X/10)<>0 THEN 100

90 Y=1

100 AA=Y:RETURN

110 'ｷ-ﾆｭｳﾘｮｸ

120 B$=INKEY$:IF B$="Q" THEN B=0:RETURN

130 IF B$="W" THEN B=1:RETURN

140 IF B$="/" THEN B=8:RETURN

150 IF B$="*" THEN B=2:RETURN

160 IF B$="A" THEN B=4:RETURN

170 IF B$<>"6" THEN 120

180 LOCATE 9,0:PRINT H;"FL:LV";P:LOCATE 9,0:PRINT Q;"HP:EX";T

190 LOCATE 9,0:PRINT R;"SW:EN";S;" ":LOCATE 9,0:PRINT W;"ABR:P";I;" ";

200 B=3:GOTO 1080

210 'ﾒｲﾛ ﾋｮｳｼﾞ

220 CLS

230 IF P3>0 THEN PRINT MID$(C$,P3+4,1);:GOTO 250

240 IF P4>0 THEN PRINT MID$(C$,P4+8,1);

250 PRINT TAB(1);:IF P1>0 THEN PRINT MID$(C$,P1+8,1);:GOTO 270

260 IF P2>0 THEN PRINT CHR$(165);

270 PRINT TAB(2);:IF P5>0 THEN PRINT MID$(C$,P5+12,1);:GOTO 290

280 IF P6>0 THEN PRINT MID$(C$,P6+8,1);

290 PRINT TAB(3);Z/10;MID$(C$,G,1);

300 GOSUB 120

310 IF B<>1 THEN 390

320 'ﾐｷﾞｦ ﾑｸ

330 G=G-1:IF G<1 THEN G=4

340 P3=P1:P4=P6:P1=P5

350 IF G=1 THEN X=Z+10:GOSUB 40:P5=AA:X=Z+9:GOSUB 40:P6=AA:IF P1<>1 THEN X=Z-2:GOSUB 40:P2=AA

360 IF G=2 THEN X=Z-1:GOSUB 40:P5=AA:X=Z-11:GOSUB 40:P6=AA:IF P1<>1 THEN X=Z-20:GOSUB 40:P2=AA

370 IF G=3 THEN X=Z-10:GOSUB 40:P5=AA:X=Z-9:GOSUB 40:P6=AA:IF P1<>1 THEN X=Z+2:GOSUB 40:P2=AA

380 IF G=4 THEN X=Z+1:GOSUB 40:P5=AA:X=Z+11:GOSUB 40:P6=AA:IF P1<>1 THEN X=Z+20:GOSUB 40:P2=AA

390 IF B<>0 THEN 470

400 'ﾋﾀﾞﾘｦ ﾑｸ

410 G=G+1:IF G>4 THEN G=1

420 P5=P1:P6=P4:P1=P3

430 IF G=1 THEN X=Z-10:GOSUB 40:P3=AA:X=Z-11:GOSUB 40:P4=AA:IF P1<>1 THEN X=Z-2:GOSUB 40:P2=AA

440 IF G=2 THEN X=Z+1:GOSUB 40:P3=AA:X=Z-9:GOSUB 40:P4=AA:IF P1<>1 THEN X=Z-20:GOSUB 40:P2=AA

450 IF G=3 THEN X=Z+10:GOSUB 40:P3=AA:X=Z+11:GOSUB 40:P4=AA:IF P1<>1 THEN X=Z+2:GOSUB 40:P2=AA

460 IF G=4 THEN X=Z-1:GOSUB 40:P3=AA:X=Z+9:GOSUB 40:P4=AA:IF P1<>1 THEN X=Z+20:GOSUB 40:P2=AA

470 IF B<>8 OR P1=1 THEN 560

480 'ｾﾞﾝｼﾝ

490 Z=Z-(G=4)*10-(G=3)+(G=2)*10+(G=1)

500 C=P1+1:P3=P4:P1=P2:P5=P6 

510 IF G=1 THEN X=Z-11:GOSUB 40:P4=AA:X=Z+9:GOSUB 40:P6=AA:IF P1<>1 THEN X=Z-2:GOSUB 40:P2=AA

520 IF G=2 THEN X=Z-9:GOSUB 40:P4=AA:X=Z-11:GOSUB 40:P6=AA:IF P1<>1 THEN X=Z-20:GOSUB 40:P2=AA

530 IF G=3 THEN X=Z+11:GOSUB 40:P4=AA:X=Z-9:GOSUB 40:P6=AA:IF P1<>1 THEN X=Z+2:GOSUB 40:P2=AA

540 IF G=4 THEN X=Z+9:GOSUB 40:P4=AA:X=Z+11:GOSUB 40:P6=AA:IF P1<>1 THEN X=Z+20:GOSUB 40:P2=AA

550 ON C GOTO 620,220,660,680,710

560 IF B=4 THEN G=G-2:IF G<1 THEN G=4+G

570 IF B=4 THEN 1380

580 IF B=2 AND I>0 THEN 1050

590 IF B=8 AND P1=1 THEN 300

600 GOTO 220

610 'ﾃﾞｸﾜｽ ﾓﾉ

620 IF RAN#<.3 THEN GOSUB 730

630 IF RAN#>.3 THEN 220

640 L=H+INT(RAN#*2:M=L^2+5:U=3*L+2:PRINT "ENEMY!";:GOSUB 800:GOTO 220

650 'ﾏｸﾗ ｹﾞｯﾄ

660 PRINT "GET PLW";:I=9:GOSUB 1080:GOTO 220

670 'ﾚﾍﾞﾙ ｱｯﾌﾟ?

680 E=(P+2)^2:PRINT "NX";E;:GOSUB 1080:IF T<E THEN 220

690 PRINT "LV UP!";:P=P+1:T=0:GOSUB 1080:GOTO 220

700 'ﾃﾝｼ ｼｭﾂｹﾞﾝ

710 PRINT "ANGEL!";:M=H^2*6+20:U=8+INT(H^2/3:L=1:Y=8:GOSUB 800:GOTO 220

720 'ﾂﾙｷﾞ ｹﾞｯﾄ

730 E=INT(RAN#*H^2+3:J=1:PRINT "FIND SW";

740 LOCATE 0,1:PRINT E;"SW:";MID$(C$,17+3*J,3);

750 GOSUB 120:IF B=0 THEN J=0 ELSE IF B=1 THEN J=1

760 IF B<>8 THEN 740

770 IF J=0 THEN PRINT ":EQUIP!";:R=E:S=INT(10*RAN#+8)

780 GOSUB 1080:RETURN

790 'ﾃｷ ｽｶﾞﾀｦ ﾛ-ﾄﾞ

800 N=0:RESTORE INT((L-1)/2)*10+1060:READ N$:IF FRAC(L/2)=0 THEN READ N$

810 DEFCHR$(252)=N$:IF Y=8 THEN DEFCHR$(252)="70183E1870"

820 LOCATE 1,0:IF Y<8 OR H<15 THEN PRINT CHR$(252);:GOTO 870

830 RESTORE 1310:LOCATE 0,0:FOR X=0 TO 2:READ N$:DEFCHR$(252+X)=N$:PRINT CHR$(252+X);:NEXT:M=1500

840 LOCATE 9,0:PRINT "ﾊﾞｶﾒ,ｲﾏｻﾗ ﾆﾝｹﾞﾝｺﾞﾄｷｶﾞ ﾅﾝﾉﾖｳﾀﾞ.":GOSUB 1100:PRINT "ﾜﾀｼﾉ ﾏﾈｲﾀ ﾒﾂﾎﾞｳﾏﾃﾞ ｱﾄ ｽｺｼ...":GOSUB 1100

850 PRINT "ﾋﾏﾂﾌﾞｼｶ ｳｻﾊﾗｼｶ?":GOSUB 1100:PRINT "ｲｲﾀﾞﾛｳ,ｳｹﾃﾀｯﾃﾔﾙ!":GOSUB 1100

860 'ｾﾝﾄｳﾒｲﾝ

870 LOCATE 0,1:PRINT MID$(C$,23+N*5,5);:LOCATE 9,0:GOSUB 120

880 IF B=0 THEN N=N-SGN N

890 IF B=1 THEN N=N+SGN(2-N

900 IF B<>8 THEN 870

910 X=SGN S*(R+INT(RAN#*R)):IF N+RAN#>2.2 THEN GOSUB 1080:PRINT "RUN!";:GOTO 1080

920 S=S-SGN S:IF N*W=1 THEN PRINT "USE ABR";:W=0:N=0:S=10:GOTO 870

930 PRINT "HIT";X;:IF S=0 THEN PRINT ":SW BREAK";:GOSUB 1080

940 M=M-X:X=U-INT(RAN#*U:IF M<1 THEN 970

950 PRINT "DAM!";X;:Q=Q-X:GOSUB 1080:IF Q>0 THEN 870

960 Z=D:Q=48:T=INT(T/2):LOCATE 0,1:PRINT "LOSE";:GOSUB 1080:END

970 LOCATE 0,1:PRINT "WIN!!";:T=T+U:IF RAN#>.8 THEN PRINT ":ABR!";:W=1

980 GOSUB 1080:IF Y<>8 THEN RETURN

990 H=H+1:IF H<16 THEN D=F:F=INT(11+89*FRAC(TAN H*1E7:RETURN

1000 'ｵｼﾏｲ

1010 H=15:STOP:CLS:RESTORE 1340:FOR B=1 TO 6:READ N$:E=LEN(N$):FOR A=1 TO E

1020 J$=MID$(N$,A,1):IF J$="A" THEN J$=CHR$(224) ELSE IF J$="B" THEN J$=CHR$(225)

1030 J$=CHR$(ASC(J$)-3):PRINT J$;:NEXT:STOP:CLS:NEXT:END

1040 'ｷｬﾝﾌﾟ

1050 I=I-1:E=48+INT(P^2/3):Q=Q+INT(E/5):IF Q>E THEN Q=E

1060 PRINT "CAMP";Q;:GOSUB 1080:GOTO 630

1070 'ｼﾞｶﾝｶｾｷﾞ

1080 FOR V=0 TO 200:NEXT

1090 'ﾌﾞﾝｼｮｳ ｸﾘｱ

1100 LOCATE 9,0:PRINT "                       ";

1110 LOCATE 0,1:PRINT "                                ";:LOCATE 9,0:RETURN

1120 'ｹﾞ-ﾑ ｶｲｼ

1130 C=0:INPUT "9=ｻｲｼｮｶﾗ,ﾎｶ=ﾂﾂﾞｷｶﾗ",N$:IF N$<>"9" THEN 1380

1140 RESTORE 1320:FOR X=0 TO 3:READ C$:DEFCHR$(252+X)=C$:NEXT:CLS:PRINT CHR$(252);CHR$(135);CHR$(135);

1150 PRINT TAB(0);CHR$(253);CHR$(254);CHR$(255);" MOONLIT CASTLE"

1160 PRINT "ｶﾐﾄ ﾀﾀｶｲ ﾔﾌﾞﾚﾀ ﾀﾞﾃﾝｼﾊ","ｻｲｺﾞﾉ ﾃｲｺｳﾄ ｼﾃ,ﾁｷｭｳﾆ ｲﾝｾｷﾉ ｱﾒｦ ﾌﾗｾﾙｺﾄﾆｼﾀ."

1170 PRINT "ｶﾐﾉ ﾂｸﾘｼ ﾆﾝｹﾞﾝﾀﾁｦ ﾐﾁﾂﾞﾚﾆ ｽﾙﾀﾒﾀﾞ.","ｻｲﾊ ﾅｹﾞﾗﾚ,ﾓﾊﾔ ﾁｷｭｳﾒﾂﾎﾞｳｦ ﾄﾒﾙ ｽﾍﾞﾊ ﾅｲ."

1180 PRINT "ﾎﾛﾋﾞﾕｸ ｾｶｲﾃﾞ,ｱﾅﾀﾊ ｹﾞﾝｷｮｳﾉ ﾀﾞﾃﾝｼﾆ ﾌｸｼｭｳｼﾖｳﾄｽﾙ.","ｿﾚｶﾞ ｲﾏﾔ ﾏｯﾀｸ ｵﾛｶﾅｺｳｲﾃﾞ ｱﾙﾄ,ﾑｴｷﾃﾞ ﾑｶﾁﾅﾀﾀｶｲﾃﾞ ｱﾙﾄ ｼﾘﾅｶﾞﾗ..."

1190 CLEAR:G=4:H=1:Z=55:C$=CHR$(227)+CHR$(228)+CHR$(229)+CHR$(230):DEFCHR$(255)="00FEFEFE00"

1200 C$=C$+"])>I"+CHR$(236)+CHR$(237)+CHR$(238)+CHR$(227)+"[(<I"

1210 C$=C$+"GETTRWFIGHTABR  RUN  ":R=3:S=10:Z=99:D=Z:Q=48:P=1:F=15:GOTO 1450

1220 'ﾃｷﾉ ｽｶﾞﾀ ﾃﾞ-ﾀ

1230 DATA060E0E0A06,7820702078

1240 DATAF0307E2C00,20B678B620

1250 DATAE214381462,0042720E02

1260 DATAAC703070AC,08107E3C30

1270 DATA18F27CF218,6076F87640

1280 DATA74DAF6DA74,70F80A1C0A

1290 DATA04CA32C20C,087C7E10F0

1300 DATA303AFEFC3A,167EBE7E16

1310 DATA00183C7060,D0207E20D0,60703C1800

1320 DATAFEF6F6CEFE,FEFEDE90DE,E0AEA8AEA0,A0B0DE90DE

1330 'ｴﾝﾃﾞｨﾝｸﾞ ﾒｯｾ-ｼﾞ

1340 DATAｴﾈﾃﾍ#ﾃBﾆAｿｩ#ﾃｸｿﾃ1,ｿｹｿ/ﾕﾅﾑBｶﾍ#ﾇﾕﾚﾝﾈｵ1

1350 DATAｿﾞﾍ#ﾑｶｹｵｿﾆｵｻ1,ｾｵｽBﾉ#ｴﾈﾃﾍ#ｵﾌｲﾃ1

1360 DATAﾃBﾝﾖｹB#ｿｴﾟﾁﾌ#ｶﾄﾉ#ｿﾋﾒﾀﾙｶﾉ111ﾇ1,ILQ1

1370 'ﾒｲﾛ ｺｳﾁｸ

1380 ON G GOTO 1390,1410,1430,1450

1390 X=Z-1:GOSUB 40:P1=AA:X=Z-2:GOSUB 40:P2=AA:X=Z-10:GOSUB 40:P3=AA

1400 X=Z-11:GOSUB 40:P4=AA:X=Z+10:GOSUB 40:P5=AA:X=Z+9:GOSUB 40:P6=AA:GOTO 220

1410 X=Z-10:GOSUB 40:P1=AA:X=Z-20:GOSUB 40:P2=AA:X=Z +1:GOSUB 40:P3=AA

1420 X=Z-9:GOSUB 40:P4=AA:X=Z-1:GOSUB 40:P5=AA:X=Z-11:GOSUB 40:P6=AA:GOTO 220

1430 X=Z+1:GOSUB 40:P1=AA:X=Z+2:GOSUB 40:P2=AA:X=Z+10:GOSUB 40:P3=AA

1440 X=Z+11:GOSUB 40:P4=AA:X=Z-10:GOSUB 40:P5=AA:X=Z-9:GOSUB 40:P6=AA:GOTO 220

1450 X=Z+10:GOSUB 40:P1=AA:X=Z+20:GOSUB 40:P2=AA:X=Z-1:GOSUB 40:P3=AA

1460 X=Z+9:GOSUB 40:P4=AA:X=Z+1:GOSUB 40:P5=AA:X=Z+11:GOSUB 40:P6=AA:GOTO 220