10 '=STRUGGLERS 2024= VER.1.0 BY YONAPUU,2024
20 GOTO 710
30 'ｶｲｼﾞｮ
40 C=X:G=A:Q=W:RETURN
50 D=X:H=A:R=W:RETURN
60 'ﾒｲﾝ
70 LOCATE 0,1:PRINT "          ";M;:LOCATE H,1:PRINT F$;:LOCATE G,1:PRINT E$;
80 Z=Z+1:B=INT(RAN#*3-1):IF RAN#>.9 THEN B=3
90 IF ABS(G-H)<=RAN#*3 THEN B=INT(RAN#*2+2)
100 K=0:X=C:A=G:P=H:L=I:W=Q:T=SGN(H-G):IF C<>0 THEN GOSUB 320:GOSUB 40:GOTO 150
110 IF INKEY$="Q" THEN G=G-SGN G:GOTO 160
120 IF INKEY$="W" THEN G=G+SGN(10-G):GOTO 160
130 IF INKEY$="/" THEN GOSUB 250:X=C:A=G:P=H:L=I:W=Q:T=SGN(H-G)
140 IF INKEY$="*" THEN GOSUB 320:GOSUB 40
150 IF INKEY$="/" THEN GOSUB 250:C=0:X=0:GOSUB 40
160 K=1:X=D:A=H:P=G:L=J:W=R:T=SGN(G-H):IF D<>0 THEN GOSUB 320:GOSUB 50:GOTO 200
170 IF B=-1 THEN H=H-SGN H
180 IF B=1 THEN H=H+SGN(10-H)
190 IF B>=2 THEN ON B GOSUB ,250,320:GOSUB 50
200 IF M<=0 THEN GOSUB 850:LOCATE 1,1:PRINT "[GAMEOVER]":END
210 IF N>=1 THEN 70
220 LOCATE 3,1:PRINT "[WIN!]";:GOSUB 850:IF J<=9 THEN 820
230 GOTO 870
240 'ｺﾜｻﾞ
250 IF T=0 THEN 280
260 LOCATE A+T,1:PRINT "-";:IF A+T<>P THEN RETURN
270 V=1:GOTO 650
280 FOR S=1 TO 3:GOSUB 270
290 A=A+SGN(5.5-P):LOCATE A,1:PRINT "#";:NEXT S:IF K=0 THEN G=A:T=SGN(H-G):RETURN
300 H=A:T=SGN(G-H):RETURN
310 'ｵｵﾜｻﾞ
320 IF X=0 THEN W=T:IF T*FRAC SQR L=0 THEN X=A*ABS T:IF T=0 THEN RETURN
330 T=SGN W:X=X+T:S=ABS X:U=A+T:ON L GOTO 340,350,380,420,430,450,480,510,550,570
340 V=3:GOTO 610
350 IF S=1 THEN RETURN
360 LOCATE U,1:PRINT "=";:V=7:IF U<>P THEN X=0:RETURN
370 FOR S=11 TO 15:LOCATE P,1:PRINT MID$($,S+SIN PI,1);:NEXT S:GOTO 650
380 LOCATE A,1:PRINT "z";:IF S<=2 THEN RETURN
390 LOCATE U,1:PRINT CHR$(135);CSRU+T*SGN FRAC(U/10);CHR$(135);
400 IF P<>U THEN IF P<>U+T THEN X=0:RETURN
410 V=4:GOTO 650
420 V=4:X=S+T*SGN S:GOTO 610
430 V=3:A=10-A:T=-T:IF A=P THEN 650
440 X=0:RETURN
450 IF S=1 THEN A=U:RETURN
460 IF U=P THEN FOR Y=0 TO 2:GOSUB 250:NEXT Y
470 X=0:RETURN
480 IF S=1 THEN W=P:LOCATE P,1:PRINT "'";:X=2:RETURN
490 LOCATE W,1:PRINT CHR$(229);:V=3:T=SGN(P-A):IF P=W THEN 650
500 X=0:RETURN
510 LOCATE A,1:PRINT "Y";:V=3:IF S<=2 THEN RETURN
520 FOR S=0 TO 2:IF ABS(A+T-5)<=5 THEN A=A+T
530 LOCATE A,1:PRINT "\";:IF A=P THEN GOSUB 650:S=2
540 NEXT S:X=0:RETURN
550 V=2:GOSUB 610:S=X:IF S<>0 THEN S=S+T:X=S:GOTO 610
560 RETURN
570 LOCATE A,1:PRINT CHR$(238);:V=4:IF S=1 THEN RETURN
580 FOR S=1 TO 3:Y=2*S*T+A:IF ABS(Y-5)<=5 THEN LOCATE Y,1:PRINT "V";:IF Y=P THEN 650
590 NEXT S:X=0:RETURN
600 'ﾋｼｮｳﾀｲ
610 LOCATE S,1:PRINT MID$($,14+V,1);:IF S=P THEN GOSUB 650
620 IF S>9 THEN X=0
630 RETURN
640 'ﾀﾞﾒｰｼﾞ
650 LOCATE P,1:PRINT "*";:IF K=1 THEN 670
660 N=N-V:H=P+T*SGN FRAC(P/10):B=0:GOTO 690
670 M=M-V:G=P+T*SGN FRAC(P/10):GOTO 690
680 'ｶｸｼｭｶｲｼﾞｮ
690 C=0:D=0:X=0:RETURN
700 'ｼｮｷｶ
710 INPUT "9=ｷﾛｸﾘｾｯﾄ,ﾎｶ=ｽﾀｰﾄ",E$:IF E$<>"9" THEN 740
720 CLEAR:E$="":F$="":M=0:H=0:G=0:Z=0:B=0:K=0:X=0:L=0:A=0:P=0:I=0:J=0:W=0:C=0:D=0:T=0
730 Q=0:R=0:DIM A(11):DIM B$(11):RESTORE 910:FOR A=1 TO 10:A(A)=999:READ B$(A):NEXT A
740 I=1:J=0:Z=0:CLS:PRINT "-=STRUGGLERS 2024=-";:$=CHR$(235)+CHR$(133)
750 $=$+CHR$(231)+CHR$(141)+CHR$(232)+"&"+CHR$(233)+"\"+CHR$(132)+CHR$(234)
760 E$="="+CHR$(240):$=$+E$+E$+"="+CHR$(159)+CHR$(226)+"+"
770 E$=MID$($,I,1):LOCATE 0,1:PRINT "SELECT=";E$;":                     ";
780 LOCATE 9,1:PRINT B$(I);A(I);
790 IF INKEY$="Q" THEN I=1+I*SGN(10-I:GOTO 770
800 IF INKEY$<>"/" THEN 790
810 LOCATE 7,1:PRINT "                    ";
820 J=J+1:GOSUB 690:LOCATE 0,1:PRINT "  ROUND";J;:GOSUB 850
830 M=9:N=9:G=3:H=7:F$=MID$($,J,1):GOTO 70
840 'ｼﾞｶﾝｶｾｷﾞ
850 FOR O=0 TO 350:NEXT O:LOCATE 0,1:PRINT "            ";:RETURN
860 'ｴﾝﾃﾞｨﾝｸﾞ
870 F$="ﾔｯﾀｾﾞ!ﾐﾀｶ-ｯ!ｳﾚｼｲﾅｧﾆﾝﾆﾝ..ﾄﾞｳﾀﾞ!ﾊﾞﾝｻﾞｲ...ﾌﾝ!ﾊﾊﾊﾊﾊﾊﾊﾞｶﾒｯ!ﾑﾀﾞﾀﾞﾖ"
880 FOR S=0 TO 9:LOCATE S,1:PRINT E$;:GOSUB 850:NEXT S
890 LOCATE 0,1:PRINT "(";MID$(F$,I*6-5,6);"!>";E$;" TIME";Z;:IF Z>A(I) THEN STOP:END
900 A(I)=Z:LOCATE 31,1:INPUT " ｻｲｺｳｷﾛｸ! ﾅﾏｴ=",B$(I)
910 DATAﾑｴﾀｲｾｲﾈﾝ,ﾊﾟﾝﾔﾉﾃﾝﾁｮｳ,ｶﾌﾞｷﾑｽﾒ,ｼﾞｼｮｳﾆﾝｼﾞｬ,ｷｺｳｼﾞｭﾂﾉﾛｳｼﾞﾝ,ｳﾂﾍﾞｼｵﾔｼﾞ,ﾃﾞﾝｷ,ﾊﾘｭｳﾃｲ,ﾊｺﾞｸｵｳ,ﾊｶｲｼﾝ