MAGICAL RING プログラム

■ＭＡＧＩＣＡＬ　ＲＩＮＧ■
　著作制作…………よなぷー
　制作年月日………２０１５年６月１７日
　対応機種…………ＰＢ－１００／１１０／１２０用ゲームプログラム
　使用メモリ………１５６８ステップ
　※「クラブ」「スペード」「ハート」は、その記号を入力してください。
　※「●」はスペース一個です。
　※「○」はEXTモードの[SHIFT][A]です。
　※「⊂」は[ANS]の下の[E]です。

◆◆◆ P0 ◆◆◆

2 GOSUB #1

4 $=M$(Y):PRINT CSR0;$;B;"●";CSRX;"Ω";:IF F=Y;PRINT CSRE;G$;

6 IF MID(X+1,1)="■";GOSUB #3:PRINT CSR7;B;"●";CSRX;"Ω";

8 GOSUB #8:IF F=Y;IF E=X;GOSUB #2

20 IF C≠9 THEN 35

25 D$=MID(X+1,1):IF D$="○";GOSUB #7:GOTO 2

30 IF D$="□";GOSUB #6:GOTO 4

35 H=H+1:IF H≦6 THEN 8-SGNC*4

40 H=0:C=X-E:IF F=Y;IF ABSC=1;GOSUB #3:GOTO 4

45 IF F=Y;IF L>4;IF ABSC>2;IF RAN#>.3 THEN 60

50 D=INT(RAN#*3-1:IF ABS(E+D-3<4;E=E+D

55 GOTO 4

60 FOR D=SGNC TO C STEP SGNC:PRINT CSRE+D;"-";:NEXT D

65 GOSUB #3:GOTO 4


◆◆◆ P1 ◆◆◆

10 $="△クラブ△_□■△□クラブ_nπμtx÷e↑":FOR C=1 TO 5:L(C)=0

20 FOR D=1 TO 7:L$(C)=L$(C)+MID(1+10*FRAC(π/L*3⊂4*D/C,1)

30 NEXT D:PRINT:PRINT "Loading=";C;:NEXT C:G$=MID(L+10,1)

40 C=INT(RAN#*5+2:D=INT(RAN#*5:$=M$(D)

50 M$(D)=MID(1,C-1)+"○"+MID(C+1):GOTO #4


◆◆◆ P2 ◆◆◆

10 PRINT CSRE;"*";:IF C=1;U=0

20 IF C≧4;U=U-Z:X=X-SGN(C-5

30 IF U≧1;RETURN

40 PRINT CSRE;"・";:J=J+L↑2:GOTO #4


◆◆◆ P3 ◆◆◆

10 PRINT CSRX;"×";:B=B-2:IF B≧1;RETURN

20 B=20:J=INT(J/2:GOSUB #4


◆◆◆ P4 ◆◆◆

10 H=0:E=INT(RAN#*7:F=INT(RAN#*5:U=L↑2:IF F=Y;F=ABS(F-1

20 RETURN


◆◆◆ P5 ◆◆◆

10 FOR W=0 TO 99:NEXT W:RETURN


◆◆◆ P6 ◆◆◆

3 PRINT:PRINT "Shop","HpMax":B=20:$="Swd●Exit":E=0:D=2:R=X:S=Y

6 PRINT:PRINT MID(E*4+1,4);:IF E=0;PRINT CSR3;D;":";D↑3;

9 GOSUB #8:IF C=4;D=2+D*SGN(20-D:GOTO 6

20 IF C=6;E=1-E:GOTO 6

30 IF C=8 THEN 6

40 IF C≠9 THEN 9

50 IF E=0;IF D>Z;IF J≧D↑3;J=J-D↑3:Z=D:PRINT:PRINT "GetNewSwd!"

60 IF E=1;X=R:Y=S:RETURN

70 GOTO 6


◆◆◆ P7 ◆◆◆

4 $="GPCJANKENPON◆%&￥$スペード@Σ":G$=MID(L+12,1):U=L↑2*2:PRINT CSRX;"!"

8 PRINT CSR0;"●";G$;"●●●Ω●";B;"●";:H=0:FOR T=0 TO 2

20 PRINT CSR2;MID(T*3+4,3);:GOSUB #5:NEXT T:E=INT(RAN#*3

30 D=INT(RAN#*3:PRINT CSR0;MID(E+1,1);CSR6;MID(D+1,1);

40 IF E=0;IF D=2;E=3

50 IF E=2;IF D=0;D=3

60 F=0:IF D>E;F=1

70 IF D=E;PRINT CSR2;"●A●";:GOSUB #5:GOTO 8

80 H=H+1:GOSUB #8:IF C=4;PRINT CSR2;"←←←";:H=4

90 IF C=9;PRINT CSR5;"[";:H=4

100 IF H<4 THEN 80

110 IF F=1;PRINT CSR1;"]";:IF C=4;PRINT CSR1;"*";:U=U-Z

120 IF F=0;PRINT CSR2;"→→→";:IF C≠9;X=5:B=B-INT(L/2:GOSUB #3

130 GOSUB #5:IF U≧1 THEN 8

140 PRINT "Win":IF L<8;PRINT "GoNextWorld!":L=L+1:X=0:Y=0:RETURN

150 PRINT "Regain●Ring!","Become●Peace","You●Are●Hero","THEEND";


◆◆◆ P8 ◆◆◆
10 C=0:IF KEY="W";Y=Y+1:C=1:IF Y>4;Y=0

20 IF KEY="X";Y=Y-1:C=1:IF Y<0;Y=4

30 IF KEY="A";X=X-SGNX:C=4

40 IF KEY="D";X=X+SGN(6-X:C=6

50 IF KEY="+";C=9

60 IF KEY="3";PRINT:PRINT L;"Wld:Hp";B,Z;"S:G";J:C=8

70 RETURN


◆◆◆ P9 ◆◆◆

10 PRINT "MAGICAL●RING":VAC:L=1:Z=1:B=20:GOTO #0

MAGICAL RING 紹介

■ＭＡＧＩＣＡＬ　ＲＩＮＧ■
　著作制作…………よなぷー
　制作年月日………２０１５年６月１７日
　対応機種…………ＰＢ－１００／１１０／１２０用ゲームプログラム
　使用メモリ………１５６８ステップ
　※「クラブ」「スペード」「ハート」は、その記号とみなしてください。
　※「●」はスペース一個です。
　※「○」はEXTモードの[SHIFT][A]です。
　※「⊂」は[ANS]の下の[E]です。

【　変数表　】
Ａ　　―――
Ｂ　　自分体力
Ｃ　　汎用
Ｄ　　汎用
Ｅ　　汎用
Ｆ　　汎用
Ｇ＄　敵姿
Ｈ　　敵動作カウンタ
Ｉ　　―――
Ｊ　　お金
Ｋ　　―――
Ｌ　　ワールド
Ｍ＄　地形１
Ｎ＄　地形２
Ｏ＄　地形３
Ｐ＄　地形４
Ｑ＄　地形５
Ｒ　　Ｘ保存用
Ｓ　　Ｙ保存用
Ｔ　　ループ用
Ｕ　　敵体力
Ｖ　　―――
Ｗ　　時間稼ぎ
Ｘ　　自分横座標
Ｙ　　自分縦座標
Ｚ　　剣の威力

【　プログラムエリア表　】
Ｐ０　地上メイン
Ｐ１　地形作成
Ｐ２　攻撃
Ｐ３　ダメージ
Ｐ４　敵発生
Ｐ５　時間稼ぎ
Ｐ６　店
Ｐ７　ボスバトル
Ｐ８　キー入力
Ｐ９　初期設定

【　物語　】
　この世から混沌が一掃されたとき、大いなる力を発揮したといわれる魔法の指輪。一ヶ月前、その指輪が魔物たちに奪われ、地上から平和が失われた。事態を憂えた国王は、魔の大地に赴いて指輪を取り返してくれる勇者を募った。
　そうしてあなたが現れたのである。

【　遊び方　】
　［ＳＨＩＦＴ］［９］でスタート、［ＳＨＩＦＴ］［０］でコンティニュー。
　上下の繋がった地上マップを、［Ｗ］［Ａ］［Ｄ］［Ｘ］で上下左右に移動します。敵と戦う方法は体当たりですが、横から当たった場合は剣の威力分のダメージを与え、縦から当たった場合は敵体力関係なく一撃で倒します。「■」は毒沼で、入ると自分の体力が２ずつ減っていきます。「□」（店）、「○」（ボスの洞窟）には［＋］で入ります。
　店では体力が回復し、剣を購入できます。［Ａ］で威力を変更、［＋］で購入します。店を出る場合は［Ｄ］で「Ｅｘｉｔ」を選択、［＋］を押してください。
　ボスの洞窟ではボスと、いわゆる「叩いて被ってジャンケンポン」で勝負します。 「Ｐ」はパー、「Ｇ」はグー、「Ｃ」はチョキです。ボスの手に勝った場合は［Ａ］で攻撃、負けた場合は［＋］で防御してください。攻撃に成功すると剣の威力の分だけダメージを与え、倒すと次のワールドに進みます。
　以上のどの場面においても、［３］で自分の状態を見られます。順に、ワールドと体力、剣の威力とお金が表示されます。
　第８ワールドのボスを倒すか、体力が０になるとゲームオーバーです。後者の場合、お金が半分になってしまいます。

【　開発後記　】
　久しぶりにオリジナルゲームに挑戦してみました。なかなか面白いと思います……と自画自賛（ローディングが長いですが）。後半面では敵雑魚が飛び道具を使ってくるので気をつけましょう。

ヒョードルの新技

ヒョードルが「新技ができた」と発表したため、記者団が嫌々集まった。

ヒョードル「本日お呼びしたのは他でもない。新技ができたんです」

ヒョードルは隣に立っていたノゲイラに組み付き、「天龍！」と叫びながらパワーボムを敢行した。

ヒョードル「今のが『天龍ボム』。『天龍！』と叫ぶ以外は通常のパワーボムと同じです。次に……」

ヒョードルはノゲイラを介抱していたミルコの腕をロックし、『三沢！』と叫びながらタイガードライバーを決めた。

ヒョードル「今のが『三沢ドライバー』。『三沢！』と叫ぶ以外は通常のタイガードライバーと同じです」

説明を終える頃には大半のマスコミが帰っており、会見場は閑散としていた。

記者「他に何か言いたいことは？」

ヒョードル「この二大必殺技を用いて、新日本プロレス全盛の今のプロレス界に風穴を開けたいと思います」

そこへ三沢さん登場。

三沢さん「やあ、お疲れ、ヒョードル君」

ヒョードル「み、みみみ三沢さん！」

三沢さん「すれ違いに記者から聞いたけど、『三沢ドライバー』って技を覚えたそうだね。俺、全然話聞いてないんだけど」

ヒョードル「それは……その……」

三沢さん「俺の許可なく三沢をかたるなんて、あまりにもおこがましくないか？」

ヒョードル「（土下座して）ははーっ」

三沢さん「今日は許してやるけど、今後俺の名を無許可で使ったら、問答無用で『これ』だからね」

と言って右肘を素振りする。

ヒョードル「（滝のように汗をかき）承知いたしました」

三沢さん「分かったね？　それじゃ」

三沢さんは帰っていった。

ヒョードル「せっかく三沢ドライバーを開発したのに……」

三沢さんが駆け足で戻ってきた。

三沢さん「やっぱり許せん！」

三沢さんのランニングエルボーがヒョードルの左側頭部に炸裂した。

ヒョードル「うぎゃあっ！」

昏倒するヒョードル。

三沢さん「やっぱり八百長野郎に技名だとしても呼び捨てにされるのはね。あーすっきりした」

やっぱり三沢さん最強！

デストラップダンジョンの表紙問題

スティーブ・ジャクソンと双璧をなすゲームブック作家、イアン・リビングストン。

彼がツイッターで、自著『デストラップ・ダンジョン』の日本語版（２００８年ホビージャパン）の表紙を嘆いている。

原作や社会思想社の日本語版『死のワナの地下迷宮』には、怪物の振り向く絵が使われていた。

しかしホビージャパン版は一転、水着アーマーの美少女が剣を振りかざす「日本の萌え絵」が使われたのである。

リビングストンはこれが気に入らなかったらしく、愚痴をこぼしたらしい。

ネットでは同情する声が多出したが、「元の絵なら手に取らない」との意見もあった。

しかし問題は、なぜ７年も経っていきなりリビングストンが文句を言いだしたか、だ。

まさか７年間、この萌え表紙を知らなかったというわけでもあるまい。

ホビージャパンから頼まれたのでは、と邪推してしまう。

どうあれゲームブックに注目を集めるには、これはいい宣伝となっただろう。

何とか売れてくれると、ゲームブックファンとしては嬉しい。

決め技再生

技再生というか、見直し必殺技と言うべきものが、プロレス界にはある。

例えば鈴木秀樹のダブルアームスープレックス。

例えば鈴木鼓太郎のタイガードライバー。

例えば石井智宏の垂直落下式ブレーンバスター。

いずれも、最初は決め技として定着していたが、時代の流れにより繋ぎ技に定着。

しかしその後、これらの選手が再び決め技として使い始めたものだ。

個人的にはいいことだと思う。

唯一無二の必殺技として、定着するまで使い続けてほしい。