WILD TIMES プログラム

■ＷＩＬＤ　ＴＩＭＥＳ■

　著作制作…………よなぷー
　制作年月日………２０１５年８月４日
　対応機種…………ＰＢ－１００／１１０／１２０用ゲームプログラム
　使用メモリ………プログラム本体　１４８０ステップ
　　　　　　　　　ＤＥＦＭ命令　　　　８８ステップ
　※「クラブ」「スペード」「ハート」は、その記号を入力してください。
　※「●」はスペース一個です。
　※「○」はEXTモードの[SHIFT][A]です。
　※「⊂」は[ANS]の下の[E]です。


◆◆◆ P0 ◆◆◆

9 FOR B=0 TO 4:PRINT CSRB*2;H(B);:NEXT B:PRINT CSR2*A;"→";

20 IF H+I+J+K+L=0;PRINT CSR11;"●Unification!",CSR3;"THEEND";:END

30 IF H(A)=0;GOSUB #1:IF B=0 THEN 9

40 C=Z(A+2):C=C-INT(M(A)/50:IF C≦0;C=0

50 Z(A+2)=C:A=A+1:IF A≧5;A=0

60 IF H(A)=0 THEN 9

70 M(A)=M(A)+2:E=INT(RAN#*9:IF E≦4;GOSUB #2

80 IF E≧7;B=W(A):GOSUB #3

90 IF E=5;GOSUB #4

100 IF E=6;C=Z(A+7):Z(A+7)=C+4*SGN(99-C

110 C=9:FOR B=0 TO 4:IF M(A)/3>M(B);IF H(B)≠H(A);C=B

120 NEXT B:IF C=9 THEN 9

130 E=INT(M(A)/2:F=Z(A+2):IF INT(E/4>F THEN 9

140 Z(A+2)=F-INT(E/4:GOSUB #5:GOTO 9


◆◆◆ P1 ◆◆◆

3 GOSUB #7:GOTO B*9+7

7 PRINT W(A);:INPUT B:IF B=0;RETURN

8 IF W(A)≧B THEN #3

9 B=0:RETURN

16 GOSUB #2:PRINT:PRINT "F+●20:M+";C:RETURN

25 GOSUB #4:PRINT:PRINT "Troops+";C:RETURN

34 PRINT INT(W(A)/10;:INPUT B:IF B=0;RETURN

35 IF B*10>W(A) THEN 9

36 W(A)=W(A)-B*10:C=Z(A+7):C=C+B:IF C>99;C=99

37 Z(A+7)=C:RETURN

43 GOSUB #6:IF B=0;RETURN

44 IF H(C)≠0 THEN 9

45 PRINT "Troops";M(A);:INPUT E:IF M(A)≧E;IF E≧1 THEN 47

46 GOTO 9

47 M(A)=M(A)-E:M(C)=M(C)+E:RETURN

52 GOSUB #6:IF B=0;RETURN

53 IF H(C)=0 THEN 9

54 PRINT "Troops";M(A);:INPUT E:IF E>M(A) THEN 9

55 F=Z(A+2):G=F-INT(E/4:IF G<0;PRINT "F●Lack";G*4:GOTO 9

56 Z(A+2)=G:GOTO #5

61 GOSUB #6:IF B=0;RETURN

62 PRINT "Land";C,"King";H(C),"Power";R(C),"Money";W(C)

63 PRINT "Food";Z(C+2),"Troops";M(C),"Arms";Z(C+7):GOTO 9


◆◆◆ P2 ◆◆◆

10 C=INT(R(A)/3:W(A)=W(A)+C:Z(A+2)=Z(A+2)+20:RETURN


◆◆◆ P3 ◆◆◆

10 W(A)=W(A)-B:R(A)=R(A)+INT(B/3:IF R(A)>500;R(A)=500

20 RETURN


◆◆◆ P4 ◆◆◆

10 C=INT(R(A)/5:M(A)=M(A)+C:R(A)=INT(R(A)*.9:RETURN


◆◆◆ P5 ◆◆◆

4 PRINT:PRINT "War!";H(A);"vs";H(C):M(A)=M(A)-E

8 M(C)=M(C)-INT(Z(A+7)/5+E/50+1:E=E-INT(Z(C+7)/5+M(C)/50+1

20 PRINT CSR0;E;M(C);"●●";:IF E≦0;PRINT:PRINT H(A);"Lose":RETURN

30 IF M(C)≧1 THEN 8

40 PRINT:PRINT H(A);"Win!":H(C)=H(A):M(C)=E

50 F=INT(Z(A+7)/4:Z(A+7)=F:Z(C+7)=F:RETURN


◆◆◆ P6 ◆◆◆

10 INPUT "Where",C:IF C≧5;B=0

20 RETURN


◆◆◆ P7 ◆◆◆

3 $="InvsLevyDrftBuy●MoveWar●Infm":B=0

6 PRINT CSR0;MID(B*4+1,4);"]";

9 IF KEY="Q";B=B-SGNB:GOTO 6

20 IF KEY="W";B=B+SGN(6-B:GOTO 6

30 IF KEY≠"-" THEN 9

40 RETURN


◆◆◆ P9 ◆◆◆

10 PRINT "●WILD●TIMES":VAC:INPUT "(0/1)",C

20 FOR B=0 TO 4:H(B)=B:IF C*B≠0;H(B)=1

30 M(B)=50:R(B)=20:NEXT B:GOTO #0

WILD TIMES 紹介

■ＷＩＬＤ　ＴＩＭＥＳ■

　著作制作…………よなぷー
　制作年月日………２０１５年８月４日
　対応機種…………ＰＢ－１００／１１０／１２０用ゲームプログラム
　使用メモリ………プログラム本体　１４８０ステップ
　　　　　　　　　ＤＥＦＭ命令　　　　８８ステップ
　※「クラブ」「スペード」「ハート」は、その記号とみなしてください。
　※「●」はスペース一個です。
　※「○」はEXTモードの[SHIFT][A]です。
　※「⊂」は[ANS]の下の[E]です。


【　変数表　】

Ａ　　現在の国
Ｂ　　汎用
Ｃ　　汎用
Ｄ　　―――
Ｅ　　汎用
Ｆ　　汎用
Ｇ　　汎用
Ｈ～Ｌ　　国の支配者
Ｍ～Ｑ　　兵力
Ｒ～Ｖ　　国力
Ｗ～Ｚ（１）　　予算
Ｚ（２）～Ｚ（６）　　食糧
Ｚ（７）～Ｚ（１１）　　装備


【　プログラムエリア表　】

Ｐ０　メイン
Ｐ１　各種コマンド実行
Ｐ２　徴収
Ｐ３　投資
Ｐ４　徴兵
Ｐ５　戦争
Ｐ６　対象国入力
Ｐ７　コマンド選択
Ｐ８　―――
Ｐ９　初期設定


【　物語　】
　あなたは乱世の中で、天下を統一しようと挙兵した。果たしてあなたの野望の行き着く先は……？


【　入力上の注意　】
　このゲームを遊ぶにはＤＥＦＭ命令により変数領域を拡張する必要があります。
　ＲＵＮモードで［ＤＥＦＭ１１］［ＥＸＥ］と入力し、変数を１１増やしてください。
　元に戻す場合は、［ＤＥＦＭ０］［ＥＸＥ］と入力してください。


【　遊び方　】
　［ＳＨＩＦＴ］［９］でスタート、［ＳＨＩＦＴ］［０］でコンティニュー。
　最初にどちらのモードで遊ぶか聞かれるので、「群雄割拠」なら０を、「下剋上」なら１を入力してください。
　まず全体マップが表示されます。０がプレイヤーです。矢印で指されているのが現在行動中の国となります。
　注意点として、国は１～５ではなく、０～４と数えます。例えば右から２番目の国に攻め込む場合、入力する数字は４ではなくて３です。
　また、マップ上では左から右へ国が並んでいますが、全ての国は隣接しています。戦争も移動も、左端から右端へ、あるいは４番目から２番目へ、自由自在に行なうことができます。
　自分のターンが来たら、以下のコマンドを入力します。

　１）投資（ｉｎｖｅｓｔｍｅｎｔ）
　　……国力ＵＰ（５００まで）、予算減
　２）徴収（ｌｅｖｙ）
　　……食糧・予算ＵＰ
　３）徴兵（ｄｒａｆｔ）
　　……兵力ＵＰ、国力減
　４）購入（ｂｕｙｉｎｇ）
　　……装備ＵＰ（９９まで）、予算減
　５）移動（ｍｏｖｅ）
　　……兵力移動
　６）戦争（ｗａｒ）
　　……他国侵攻、食糧減
　７）情報（ｉｎｆｏｒｍａｔｉｏｎ）
　　……自他国の情報閲覧、何回でも可

　コマンドを実行することで、以下のパラメータが増減します。

　１）国王（ｋｉｎｇ）
　　……その国の支配者です
　２）国力（ｐｏｗｅｒ）
　　……この値が高いと、徴収額や徴兵人数が増加します
　３）予算（ｍｏｎｅｙ）
　　……国力を高めたり、装備を買うのに用います
　４）食糧（ｆｏｏｄ）
　　……兵力が多いほど早く減ります。戦争出発時に必要です
　５）兵力（ｔｒｏｏｐｓ）
　　……他国へ攻め込むのに必要です
　６）装備（ａｒｍｓ）
　　……戦争時に攻撃力が増えます。装備１につき予算１０です
　　　　戦争に勝つと、元と先の両国で４分の１になります

　自国を強化して他国を攻め滅ぼし、全国統一を果たすとゲームクリアとなります。


【　開発後記　】
　光栄の『信長の野望』ライクな軍事シミュレーションに挑戦してみました。かなりいい加減です。まあ、雰囲気ぐらいは楽しめるでしょう。
　他国に仕掛けるタイミングを間違うと、食糧が尽きてどうにもならなくなります。お気をつけください。

たこの海岸物語ＰＡＲＴ３〜迷宮編

短かったＭＳＸ２（ディスクドライブなし）ユーザー時代に、好きだった投稿作品は『まものクエスト』。

しかし次点を挙げるならば、やはりそれは米屋のチャチャチャ氏制作の『たこの海岸物語ＰＡＲＴ３〜迷宮編』となる。

ＭＳＸにしては綺麗な画面で、主人公のたこを操りイカ大王を倒しに迷宮を探索する。

イベントらしいイベントはなく、謎解きは迷宮の仕掛けに集約されていた（はず。もう忘れた）。

後はイカ大王を倒すだけ、となると、勇ましい音楽がかかってプレイヤーの士気を鼓舞してくれる。

三部作の完結編にふさわしい完成度。

まだプレイしたことがないという方、ぜひお試しあれ。

殺虫剤の効き目

近頃のゴキブリって殺虫剤に耐性を持ってないか？

と思う。

昔ならひと吹きでくたばっていたはずが、今じゃ最新の殺虫剤でも仕留められない。

苦しみもがくゴキブリが物陰に逃げ込み、裏でゴソゴソうごめく……。

そんな、落ち着かない状況に追い込まれることが増えた。

最近の殺虫剤はジェットノズルで勢いがあり、命中する確率は格段に高まっている。

なのに一発で倒せないもどかしさ……。

もっと高級な殺虫剤ならいいんだろうか？

どうもよく分からん。

ＩＧＦとヒョードル

記者「猪木氏がヒョードル選手の獲得に興味を示していますが」

ヒョードル「条件は一つだね」

記者「と言うと？」

ヒョードル「八百長をやらせてくれるかどうかさ」

記者「やっぱり……」

ヒョードル「アントニオ猪木といえば異種格闘技戦という名の八百長を繰り返してきた張本人だからね。俺が八百長やりたいって言ったら二つ返事でオーケーしてくれるはずさ」

記者「ＩＧＦ参戦となれば、石井選手との再戦も浮上してきます」

ヒョードル「あの時は敗北を受け入れさせるのに苦労したよ。今回はどうかな？」

記者「知るかハゲ」