PBRY プログラム

■ＰＢＲＹ■

　著作制作…………よなぷー
　制作年月日………２０１６年２月６日
　対応機種…………ＰＢ－１００／１１０／１２０用ゲームプログラム
　使用メモリ………プログラム本体　１５２０ステップ
　　　　　　　　　ＤＥＦＭ命令　　　　４８ステップ
　※「クラブ」「スペード」「ハート」は、その記号を入力してください。
　※「●」はスペース一個です。
　※「○」はEXTモードの[SHIFT][A]です。
　※「⊂」は[ANS]の下の[E]です。


P0

1 GOSUB #1

3 PRINT:PRINT "F";E;:IF G≠0;PRINT ":S";:S(G)=S(G)-2:IF S(G)≦0;G=0

5 L=9:IF W<0;PRINT ":G";

7 $="WALKMAGCRETNGATE":GOSUB #4:GOTO H*9

9 A=RAN#+SGN G*.2:IF A>.97;PRINT:PRINT "FIND!":W=-1

10 IF A<.5;W=RAN#:X=E*2:Y=E*6:GOSUB #3

11 GOTO 3

18 GOSUB #2:GOTO 3

27 GOTO 1

36 Y=0:IF W≧0 THEN 3

37 IF FRAC(.1*(E+1≠0 THEN 40

38 W=RAN#:X=E*3:Y=E*50:PRINT CSR8;"BOSS":GOSUB #3

39 IF E=99;IF Y≦0;W=.4:Y=15⊂3:PRINT "KING":GOSUB #3

40 IF Y≠π;E=E+1:W=0:IF E>F;F=E:IF E=100;PRINT CSR3;"GREAT!";:END

41 GOTO 3


P1

1 FOR J=1 TO 3:P(J)=Z(J):S(J)=Z(J+3):NEXT J:G=0:W=0

5 $="INN-TMPLMAZE":PRINT:PRINT "TOWN";:GOSUB #4:GOTO H*9

9 IF M↑2>Z THEN 5

10 PRINT CSR8;"LVUP":Z=0:FOR L=1 TO 3:GOSUB #7:Z(L)=Z(L)+K

11 Z(L+3)=Z(L+3)+INT((14-K)/2:NEXT L:M=M+1:GOTO 1

18 GOSUB #5:$="WARRFITRSAGEMAGE":PRINT:PRINT A;M$(A);"→";:GOSUB #4

19 $="WFSM":M$(A)=MID(H,1):GOTO 5

27 E=1:RETURN


P2

2 IF L=9;GOSUB #5:L=A

4 $="FIRELIFEKEENSEEKWARP-NO-":GOSUB #4:IF S(L)≦4;H=6

6 GOSUB #7:IF H=6;RETURN

8 STOP:S(L)=S(L)-5:GOTO H*9

9 Y=Y-INT(1+(1-W)*(B*M*8:RETURN

18 GOSUB #5:B=INT(B*M*8:P(H)=P(H)+B:IF P(H)≧Z(H);P(H)=Z(H)

19 PRINT:PRINT H;":H+";B:RETURN

27 C=2:RETURN

36 G=L*(1-SGN G:RETURN

45 E=F:W=0:RETURN


P3

1 C=1:L=1

2 GOSUB 35:PRINT CSRL*2-1;"→";:IF P(L)≧1;GOSUB #4:GOSUB H*9

4 IF Y=π;RETURN

5 IF Y≦0;PRINT "WIN!":Z=Z+INT(X*1.8:RETURN

6 L=L+1:IF L=4;GOSUB 35:L=1:GOTO 40

7 GOTO 2

9 PRINT CSR0;"*";:GOSUB #7:Y=Y-INT(W*C*M*8*A+1:RETURN

18 GOSUB #2:L=L-INT(H/6:RETURN

27 IF RAN#<.3;STOP:Y=π

28 RETURN

35 $="ATCKMAGCRUN-wfm":PRINT:PRINT MID(13+W*3,1);

36 PRINT "●";N$;"●";O$;"●";P$;:RETURN

40 J=INT(RAN#*3+1:H=INT(X/J:IF P(J)≦0 THEN 40

50 PRINT CSRJ*2;"*";CSR8;H;:P(J)=P(J)-H:IF P(J)≦SIN COS TAN π;P(J)=0

60 IF Q+R+S≧1 THEN 2

70 Z=0


P4

4 H=1

8 PRINT CSR8;MID(H*4-3,4);:IF KEY="Q";H=H-SGN(H-1

20 IF KEY="W";H=H+SGN(INT(LEN($)/4)-H

30 IF KEY="-";RETURN

40 IF KEY≠"6" THEN 8

50 PRINT:PRINT "L";M,"E";Z;M↑2

60 FOR J=1 TO 3:PRINT J;M$(J),"→H";P(J),"→M";S(J):NEXT J:GOTO 8


P5

10 $="--→1--→2--→3":GOSUB #4:A=H:RETURN


P7

10 D$=M$(L):IF D$="W";A=.9:B=.1:K=12

20 IF D$="F";A=.7:B=.5:K=10

30 IF D$="S";A=.3:B=.7:K=8

40 IF D$="M";A=.1:B=.9:K=7

50 RETURN


P9

10 PRINT CSR4;"PBRY":VAC:M=1:F=1

20 FOR J=1 TO 3:M$(J)="W":Z(J)=8:Z(J+3)=8:NEXT J:GOTO #0

PBRY 紹介

■ＰＢＲＹ■

　著作制作…………よなぷー
　制作年月日………２０１６年２月６日
　対応機種…………ＰＢ－１００／１１０／１２０用ゲームプログラム
　使用メモリ………プログラム本体　１５２０ステップ
　　　　　　　　　ＤＥＦＭ命令　　　　４８ステップ
　※「ク」はクラブ、「ス」はスペード、「ハ」はハートの記号です。
　※「●」はスペース一個です。
　※「○」はEXTモードの[SHIFT][A]です。
　※「⊂」は[ANS]の下の[E]です。


【　変数表　】

Ａ　　物理攻撃力
Ｂ　　魔法攻撃力
Ｃ　　ＫＥＥＮの有無
Ｄ＄　職業チェック用
Ｅ　　現在の階
Ｆ　　最深到達階
Ｇ　　ＳＥＥＫの有無
Ｈ　　汎用
Ｉ　　―――
Ｊ　　汎用
Ｋ　　能力値ＵＰ用
Ｌ　　行動キャラ
Ｍ　　パーティーレベル
Ｎ＄～Ｏ＄　職業
Ｑ～Ｓ　　　体力
Ｔ～Ｖ　　　魔力
Ｗ　　敵タイプ
Ｘ　　敵攻撃力
Ｙ　　敵体力
Ｚ　　パーティー経験値
Ｚ（１）～Ｚ（３）　最大体力
Ｚ（４）～Ｚ（６）　最大魔力


【　プログラムエリア表　】

Ｐ０　迷宮探索
Ｐ１　街
Ｐ２　魔法
Ｐ３　戦闘
Ｐ４　キー入力
Ｐ５　メンバー指定
Ｐ６　―――
Ｐ７　職業チェック
Ｐ８　―――
Ｐ９　初期設定


【　物語　】
　あなたたち三人の冒険者は、賞金首である『暗黒の王』を倒すため、地下迷宮へと乗り込むのだった。


【　入力上の注意　】
　このゲームを遊ぶにはＤＥＦＭ命令により変数領域を拡張する必要があります。
　ＲＵＮモードで［ＤＥＦＭ６］［ＥＸＥ］と入力し、変数を６増やしてください。
　元に戻す場合は、［ＤＥＦＭ０］［ＥＸＥ］と入力してください。


【　遊び方　】
　［ＳＨＩＦＴ］［９］でスタート、［ＳＨＩＦＴ］［０］でコンティニュー。
　このゲームにはいくつかの場面がありますが、操作は全て共通です。［Ｑ］でメニューを左へ、［Ｗ］で右へ動かし、［－］で決定します。［６］を押すと現在のレベル、経験値と次のレベルアップに必要な経験値、メンバーそれぞれの体力と魔力が表示されます。この操作を行なうと左の表示が消えてしまいますが、これは仕様ですので我慢してください（すぐ慣れます）。

◎街……電源を切るたびここから始まります。入っただけで体力・魔力が全快します。
　　　　「ＩＮＮ」　宿屋です。経験値が溜まっているとレベルアップします。
　　　　「ＴＭＰＬ」寺院です。職業を変更できます。
　　　　「ＭＡＺＥ」迷宮へ入ります。
◎迷宮……「Ｆ」現在の階です。「Ｓ」ＳＥＥＫの魔法を使用中です。「Ｇ」門があります。
　　　　　「ＷＡＬＫ」迷宮を探索します。
　　　　　「ＭＡＧＣ」魔法を使います。
　　　　　「ＲＥＴＮ」一瞬で街へと戻ります。
　　　　　「ＧＡＴＥ」門が見えていれば入り、次の階へ進みます。
◎戦闘……画面左端の敵と交戦します。
　　　　　「ＡＴＣＫ」物理攻撃を加えます。
　　　　　「ＭＡＧＣ」魔法を使います。
　　　　　「ＲＵＮ」　逃げ出します。成功失敗は運任せです。
◎魔法……どの魔法でも魔力を５消費します。
　　　　　「ＦＩＲＥ」戦闘で、敵に魔法攻撃を加えます。
　　　　　「ＬＩＦＥ」かける相手を指定することで、そのメンバーの体力を回復します。
　　　　　「ＫＥＥＮ」戦闘で、物理攻撃力を倍化します。
　　　　　「ＳＥＥＫ」迷宮で、門を発見しやすくなります。一歩で魔力２を消費します。
　　　　　「ＷＡＲＰ」迷宮で、最深到達階へ移動します。
　　　　　「ＮＯ」　　魔法の使用を取りやめます。
○職業……『ＷＡＲＲ』戦士。攻撃力と体力に優れるが、魔法はからっきし駄目。
　　　　　『ＦＩＴＲ』闘士。それなりの攻撃力と魔法を操る。
　　　　　『ＳＡＧＥ』賢者。腕力はいまいちだが魔法は強い。
　　　　　『ＭＡＧＥ』魔術師。攻撃力は０に等しいが魔法は最強。

▼冒険のヒント
　・ゲーム開始時には全員戦士となっています。すぐ寺院へ行って転職しましょう。
　・戦闘では前列（左に近い側）ほど受けるダメージは大きくなります。
　・敵『ｗ』は魔法が、『ｍ』は物理攻撃が弱点です。『ｆ』はそれらの中間です。
　・「ＫＥＥＮ」は三人全員にかかります。また、重ねがけはできません。
　・戦闘時、体力０のメンバーは動けなくなります。「ＬＩＦＥ」で回復しましょう。
　・全員の体力が０になるとゲームオーバーとなり、経験値が没収されます。
　・１０階ごとにボスが出現します。
　・９９階ではボスと『暗黒の王』との二連戦となります。勝つとゲームクリアです。


【　開発後記　】
　タイトルは「ピービリィ」と読みます。ＰＢのＲＰＧでパーティープレイや職業の概念はあまり聞いたことがないので挑戦してみました。難易度は激甘です。
　『暗黒の王』を倒した後は、どこまで奥深く潜れるか試してみましょう。

カマイタチ！

テレビ朝日の『ワールドプロレスリング』でドラゴン・リー対カマイタチを観た。

カマイタチやるじゃん。

二人を知らない観客ばかりだったと思うが、見事沸かせることに成功。

一進一退の攻防の末、カマイタチが勝利、ベルト奪取。

まだ日本には帰らないという。

楽しみが増えた。

さらばエミュ

パソコンに入れてあったエミュレータを残らず消去した。

やっぱり本物がいい。

合法だし。

でもレトロフリークは高いなあ。

最近は中古ソフトも軒並み値上がりしているし……。

とても手が出せない。

メガドライブをコンプリートしたとかいう偉人には、さすがに今後一生なれそうもないな……。

ヒョードルのメール

ヒョードル「最近EメールにAAを入れるのが俺の中で流行ってるんだよ」

キングモー「いつの時代だよ」

ヒョードル「例えばこれ！　( ˘ω˘)ｽﾔｧ」

青木「ああ、眠いときには使うよね」

ヒョードル「こんなのも！　▂▅▇█▓▒░(’ω’)░▒▓█▇▅▂」

キングモー「グラデだね」

ヒョードル「( ´Д`)y━･~~ 」

青木「一服かよ！」

ヒョードル「(´・ω・`)」

キングモー「オー、気落ちしないでください」

ヒョードル「いやあ、iPhoneいじるのは楽しくて仕方ないなあ」

三沢さん登場。

三沢さん「やあ、RIZIN3馬鹿トリオ」

一同「み、みみみ三沢さん！」

三沢さん「メールなら俺もよく使ったよ。最近はLINEだけどね」

一同「ははーっ」

三沢さん「何なら俺とメアド交換するかい？　君たちの八百長交渉を封じるよう監視の意味合いも込めてね」

一同「ははーっ」

かくして3馬鹿トリオは三沢さんとメアドを交換した。

三沢さん「これで良し。じゃ、今日のところはこれで失礼するよ」

ヒョードル「よかった……今日はエルボられなかった」

三沢さん退場。

3馬鹿トリオに笑顔が戻る。

と、そこでヒョードルのiPhoneが鳴った。

ヒョードル「メール着信だ。何々……『はっきり言ってエルボーがいくよね』？」

突然壁を突き破って三沢さん来襲。

ヒョードルの顔面にランニングエルボー炸裂！

ヒョードル、ジムの壁へ人型にめり込む。

三沢さん「油断大敵ということを教えたかったんだよね」

キングモー＆青木「ははーっ」

やっぱり三沢さん最強！