PB MEMORIAL プログラム

■ＰＢ　Ｍｅｍｏｒｉａｌ■

　著作制作…………よなぷー
　制作年月日………２０１６年３月２６日
　対応機種…………ＰＢ－１００／１１０／１２０用ゲームプログラム
　使用メモリ………１５６８ステップ
　※「クラブ」「スペード」「ハート」は、その記号を入力してください。
　※「●」はスペース一個です。
　※「○」はEXTモードの[SHIFT][A]です。
　※「⊂」は[ANS]の下の[E]です。


P0

1 $="RestStdyTranSketTalkGrooDate":IF G≧0;IF FRAC SQR L=0 THEN #1

2 PRINT:PRINT K;-L;:IF G<0;PRINT ":ZZZ";:GOTO 4

3 GOSUB #2:PRINT:GOTO H*90

4 GOSUB #8:G=G+INT(RAN#*2+2:L=L+.5:IF L=13;K=K+1:L=1

5 PRINT "Stress";G;:GOSUB #8:IF G≧30;PRINT "Down!":G=-6

6 FOR J=0 TO 5:IF A(J)≦0;A(J)=0

7 NEXT J:IF K=4;IF L≧3.5 THEN 9

8 GOTO 1

9 PRINT "Sotugyo!":H=0:FOR J=1 TO 6:M=0:IF T(J)≦29 THEN 55

20 IF J=1;IF A≧40;IF F≧20;M=1

25 IF J=2;IF B≧40;IF C≧20;M=1

30 IF J=3;IF C≧40;IF D≧20;M=1

35 IF J=4;IF D≧40;IF E≧20;M=1

40 IF J=5;IF E≧40;IF B≧20;M=1

45 IF J=6;IF F≧40;IF A≧20;M=1

50 IF M=1;$="@&ΩμΣ↑":PRINT MID(J,1);:H=H+1

55 NEXT J:G=-6:L=3:$="*Happy●End!*":IF H=0;PRINT "●●Bad●End!";:END

60 PRINT ":Suki!!","Get";H;"●Girl":GOSUB #7:END

90 G=G-15:C=C-2:E=E-1:PRINT "S";G;"K";C;"U";E;:IF G≦0;G=0

100 GOTO 4

180 A=A+4:D=D+2:F=F-2:PRINT "G";A;"Z";D;"Y";F;:GOTO 4

270 C=C+4:E=E+4:D=D-2:PRINT "U";C;"K";E;"Z";D;:GOTO 4

360 B=B+4:E=E-1:PRINT "B";B;"K";E;:GOTO 4

450 D=D+4:F=F+1:A=A-2:PRINT "Z";D;"Y";F;"G";A;:GOTO 4

540 F=F+4:D=D+1:E=E-2:PRINT "Y";F;"Z";D;"K";E;:GOTO 4

630 PRINT "Dareto";:$="@Msz&MarΩYkrμSykΣArs↑Hrk-NO-":GOSUB #2

640 M=H:IF H=7 THEN 1

650 PRINT:IF A(H-1)≦14;PRINT MID(H*4-3,4);":Kyohi!";:G=G+5:GOTO 4

660 PRINT "Dokohe";:$="KoenYuenBowlDobtEigaKarkEvnt"

670 GOSUB #2:J=3:PRINT:IF H=7;IF FRAC(INT L/4≠0 THEN 1

680 IF H=7;$="HanamiPool●●C.Tree":PRINT MID(6*INT L/4-5,6):N(M)=0

690 $="FumnFutuGoodNice@&ΩμΣ↑":IF H≠7;J=INT(3*FRAC(10↑H*SIN M*π

700 PRINT:IF N(M)=H;J=0:PRINT "MaeNiKita!"

710 N(M)=H:PRINT MID(16+M,1);":";MID(J*4+1,4);:T(M)=T(M)+J

720 GOTO 4


P1

10 $="HatumodeClassGaeBunkasai@&ΩμΣ↑":PRINT MID(SQR L*8-7,8)

20 H=0:FOR J=1 TO 6:IF T(J)≧8;PRINT MID(24+J,1);:T(J)=T(J)+4:H=1

30 NEXT J:IF H=1;PRINT ":Nice!"

40 L=L+.5:GOTO #0


P2

3 H=1

6 PRINT CSR8;MID(H*4-3,4);

9 IF KEY="Q";H=H-SGN(H-1:GOTO 6

20 IF KEY="W";H=H+SGN(INT(LEN($)/4)-H:GOTO 6

30 IF KEY="-";RETURN

40 IF KEY≠"6" THEN 9

50 PRINT:PRINT "Stress";G,"Gakuryoku";A,"Bijutu";B

60 PRINT "Undo";C,"Zatugaku";D,"Konjo";E,"Yosi";F:GOTO 6


P7

10 FOR M=0 TO 5:PRINT CSR5-M;MID(1,M+1);CSR6;MID(12-M,M+1);

20 J=SIN COS TAN π:NEXT M:RETURN


P8

10 FOR N=0 TO 150:NEXT N:PRINT:RETURN


P9

10 $="*PB●Memorial":GOSUB #7:STOP:VAC:K=1:L=4:GOTO #0

PB MEMORIAL 紹介

■ＰＢ　Ｍｅｍｏｒｉａｌ■

　著作制作…………よなぷー
　制作年月日………２０１６年３月２６日
　対応機種…………ＰＢ－１００／１１０／１２０用ゲームプログラム
　使用メモリ………１５６８ステップ
　※「ク」はクラブ、「ス」はスペード、「ハ」はハートの記号です。
　※「●」はスペース一個です。
　※「○」はEXTモードの[SHIFT][A]です。
　※「⊂」は[ANS]の下の[E]です。


【　変数表　】

Ａ　　学力
Ｂ　　美術
Ｃ　　運動
Ｄ　　雑学
Ｅ　　根性
Ｆ　　容姿
Ｇ　　ストレス
Ｈ　　キー入力用
Ｉ　　―――
Ｊ　　汎用
Ｋ　　年
Ｌ　　月
Ｍ　　汎用
Ｎ　　時間稼ぎ用
Ｏ　　直前のデート場所　阿都みすず
Ｐ　　直前のデート場所　安藤まり
Ｑ　　直前のデート場所　王務ゆかり
Ｒ　　直前のデート場所　御油さやか
Ｓ　　直前のデート場所　紫熊ありさ
Ｔ　　直前のデート場所　上矢はるか
Ｕ　　好感度　阿都みすず
Ｖ　　好感度　安藤まり
Ｗ　　好感度　王務ゆかり
Ｘ　　好感度　御油さやか
Ｙ　　好感度　紫熊ありさ
Ｚ　　好感度　上矢はるか


【　プログラムエリア表　】

Ｐ０　メイン
Ｐ１　季節イベント
Ｐ２　キー入力
Ｐ３　―――
Ｐ４　―――
Ｐ５　―――
Ｐ６　―――
Ｐ７　演出効果
Ｐ８　時間稼ぎ
Ｐ９　初期設定


【　物語　】
　私立ＰＢ学園に入学したあなたは、彼女を作って幸せな学園生活を送ってみせると固く心に誓うのだった。


【　遊び方　】
　［ＳＨＩＦＴ］［９］でスタート、［ＳＨＩＦＴ］［０］でコンティニュー。
　このゲームにはいくつかの場面がありますが、操作は全て共通です。
　　［Ｑ］メニューを左へ動かす
　　［Ｗ］メニューを右へ動かす
　　［－］決定
　　［６］状態表示。順に現在のストレス、学力（Ｇ）、美術（Ｂ）、運動（Ｕ）、雑学（Ｚ）、根性（Ｋ）、容姿（Ｙ）です。左の表示が消えてしまいますが、これは仕様ですので我慢してください（すぐ慣れます）。

◎通常……現在の年－月が表示されます。
　　「Ｒｅｓｔ」行動を休んでストレスを回復させます。運動－２、根性－１。
　　「Ｓｔｄｙ」勉強します。学力＋４、雑学＋２、容姿－２。
　　「Ｔｒａｎ」トレーニングします。運動＋４、根性＋４、雑学－２。
　　「Ｓｋｅｔ」スケッチします。美術＋４、根性－１。
　　「Ｔａｌｋ」会話します。雑学＋４、容姿＋１、学力－２。
　　「Ｇｒｏｏ」身だしなみを整えます。容姿＋４、雑学＋１、根性－２。
　　「Ｄａｔｅ」女の子にデートを申し込みます。

◎デート
　　「Ｄａｒｅｔｏ」相手を選びます。「ＮＯ」で取りやめます。
　　「Ｄｏｋｏｈｅ」デートする場所を選びます。
　女の子には好きな場所、普通の場所、嫌いな場所があり、それぞれ「Ｇｏｏｄ」（良い、好感度＋２）、「Ｆｕｔｕ」（普通、好感度＋１）、「Ｆｕｍｎ」（不満、好感度＋０）と表示されます。４月、８月、１２月には「Ｅｖｎｔ」でそれぞれ花見、プール、クリスマスツリー観賞に出かけられ、これらは「Ｎｉｃｅ」（とても良い、好感度＋３）となります。また、同じ場所に続けて行くと「前に来た！」となって「Ｆｕｍｎ」となりますが、「Ｅｖｎｔ」ではそうなりません。
　　　　「Ｋｏｅｎ」公園
　　　　「Ｙｕｅｎ」遊園地
　　　　「Ｂｏｗｌ」ボウリング
　　　　「Ｄｏｂｔ」動物園
　　　　「Ｅｉｇａ」映画
　　　　「Ｋａｒｋ」カラオケ
　　　　「Ｅｖｎｔ」イベント

◎季節イベント……毎年１月（初詣）、４月（クラス替え）、９月（文化祭）に発生し、好感度が８以上の女の子は自動的に好感度が４増えます。

○女の子
　名前　　　　略　能力（主　能力（副
　阿都みすず　＠　学力　　　　容姿
　安藤まり　　＆　美術　　　　運動
　王務ゆかり　Ω　運動　　　　雑学
　御油さやか　μ　雑学　　　　根性
　紫熊ありさ　Σ　根性　　　　美術
　上矢はるか　↑　容姿　　　　学力


▼ヒント
　・ゲーム期間は１年４月～４年３月までの３年間。
　・コマンド１回ごとに半月進む。
　・ストレスが３０以上になると強制的に休ませられる。
　・女の子をデートに誘うには能力（主）が１５以上必要。
　・恋人にするには好感度３０以上・能力（主）４０以上・能力（副）２０以上が必要。


【　開発後記　】
　ＰＢ初？の恋愛ＳＬＧです。「ときめきメモリアル」が好きで作ってみました。目指せ３人同時攻略！
　なお、キー入力プログラムは「ＰＢＲＹ」のものを流用しています。便利です。

ヒョードルの道場破り３

ヒョードルが大日本プロレスに殴り込みをかけた。

ヒョードル「頼もう！　看板をもらいに来た！」

関本大介が応じる。

関本「帰れ！　お前みたいなゴロツキ、うちは相手にしていないんだ」

小林「そうだそうだ！」

ヒョードル「ふん、俺の強さに恐れをなしたか？　情けない奴らだ」

伊東「何だと？」

関本「小林さん、伊東さん、落ち着いて。ここは俺に任せてください」

ヒョードル「やるのかやらないのかはやくしろ！　それでもプロレスラーか！」

関本「よしお前、リングに上がれ。俺が相手してやる！」

ヒョードル「吐いた唾飲み込むなよ！」

ヒョードル、関本両名がリングで向かいあう。

ゴングが鳴らされた。

ヒョードル「ほらほら、来いよ！」

ヒョードル、華麗なステップでパンチを繰り出し、関本を挑発する。

関本「よし、いくぞ！」

関本、ダッシュしてショルダータックル。

ヒョードルに命中し、ヒョードルは頭から倒れた。

異変が起きた。

倒されたヒョードルが泡を吹き、ピクピクと痙攣している。

関本「あれ？　おいお前、大丈夫か？」

ヒョードルはなんとショルダータックル一発で失神していたのだ。

小林「弱っ」

伊東「激弱っ」

関本「おい救急車呼んでやれ」

やっぱりヒョードル最弱！

内藤哲也、頂点に輝く

内藤哲也が見事オカダを撃破。

念願のIWGPヘビー級ベルトを獲得した。

いやー、良かった良かった。

オカダに最多連続防衛記録を与えるために「オカダ無双」状態を作り上げるのかと思っていたから、今回のブックには大満足。

何より内藤の必殺技「デスティーノ」が格好いい。

内藤政権は長持ちするのか？

目が離せない。

彷徨う夢

彷徨う夢をよく見る。

徒歩やバス、バイクを使って目的地に向かうのだが、一向到着しない。

進めば進むほどより迷ってしまう。

遂には断崖絶壁に差し掛かり、にっちもさっちもいかなくなるのだ。

そんな夢に、二、三日に一回ぐらいの頻度で出くわしている。

理由は不明。

ネットで調べても「迷いごとがあるから」との杓子定規な回答のみでまるっきり役に立たない。

何だかなあ……。