MAZELAND プログラム

■ＭａｚｅＬａｎｄ■

　著作制作…………よなぷー
　制作年月日………２０１６年８月５日
　対応機種…………ＰＢ－１００／１１０／１２０用ゲームプログラム
　使用メモリ………１５６８ステップ
　※「ク」はクラブ、「ス」はスペード、「ハ」はハートの記号です。
　※「●」はスペース一個です。
　※「○」はＥＸＴモードの［ＳＨＩＦＴ］［Ａ］です。
　※「⊂」は［ＡＮＳ］の下の［Ｅ］です。


P0

1 FOR W=-1 TO 1:IF ABS(Y+W-9.5>9;$="■■■■■■":$=$+$+$:GOTO 4

3 GOSUB 99+Y+W

4 $="■■"+$+"■■":U$=MID(X,1):PRINT CSRW*4+4;MID(X-1,3);

5 IF W=0;S$=MID(X-1,1):T$=MID(X+1,1):L$=U$

6 IF 0>W;R$=U$

7 NEXT W:PRINT CSR3;"[";CSR7;"]";:IF Q=1;R=0:S=0:T=0:U=0

8 GOSUB #1:IF W=8;IF U$≠"■";Y=Y+1:IF Y≧20;Y=0

25 IF W=6;IF T$≠"■";X=X+1:IF X≧22;X=2

30 IF W=4;IF S$≠"■";X=X-1:IF X≦1;X=21

35 IF W=2;IF R$≠"■";Y=Y-1:IF 0>Y;Y=19

40 IF W≠1 THEN 60

45 PRINT:IF L$="□";B=A*8:PRINT "Town:HpMax!"

50 K=1:IF L$="#";PRINT "Evil!":D=20:C=650:GOSUB #2

55 IF L$="○";PRINT "Boss":D=M*3+4:C=D↑2+8:GOSUB #2

60 IF RAN#≧.8;K=0:D=M*3+2:C=D*3:GOSUB #2

65 GOTO 1

100 $="■...■■..■.クク□■.○■□":RETURN

101 $=".ク□△.■■..■.■.■.■..":RETURN

102 $="..クク.■.■...■.■..△■":RETURN

103 $="■..■■■...■■...■■..":RETURN

104 $="■.■■...■△■■.■.■.■.":RETURN

105 $="...■○■クク.■...■■.クク":RETURN

106 $=".■.■■○■■■ク.■.△○■■■":RETURN

107 $="■...■.△△.■.■■.■..○":RETURN

108 $="..■.■.■.■....■..■■":RETURN

109 $=".■..■■.クク□■△ク■■.■.":RETURN

110 $="..■■■..■.■■..■....":RETURN

111 $=".クク.■■■■■..■○■■■クク":RETURN

112 $=".□△.■.#■.□ク.■■..□△":RETURN

113 $=".△△.■■■..△△.■.■.クク":RETURN

114 $="■..○■.■■■..■■△△■..":RETURN

115 $="■■■■..■..■■..ク□.■.":RETURN

116 $="..■.□ク..■クク.■■.■..":RETURN

117 $="○.■.△ク■...■..○■..△":RETURN


P1

4 W=0

8 IF KEY="W";W=8

20 IF KEY="A";W=4

30 IF KEY="D";W=6

40 IF KEY="X";W=2

50 IF KEY="-";W=1

60 IF KEY="6";W=9

70 IF KEY="5";PRINT:PRINT A;"Lv:Hp";B,"Swd";N,"Gem";E;F;G;H:W=10

80 IF W=0 THEN 8

90 RETURN


P2

1 PRINT:PRINT "Enemy:";B;:GOSUB #1:IF W=9 THEN 7.1+RAN#

2 IF W≧2 THEN 1

3 W=INT(RAN#*5:PRINT:PRINT "Hit!";A*2+W+N:C=C-A*2-W-N:IF C≦0 THEN 9

4 PRINT:PRINT "Dam!";D:B=B-D:IF B≧1 THEN 1

5 B=1:X=5:Y=2:IF Q=0;M=0

6 END

7 PRINT:PRINT "Run!":RETURN

8 GOTO 4

9 PRINT "Win!":J=J+D:IF J≧A↑2/2+4;A=A+1:J=0:PRINT "LvUp!"

20 IF K=0;RETURN

30 W=0:IF M≦3;M=M+1

40 IF X=7;W=1

50 IF X=17;W=2

60 IF X=8;W=3

70 IF X=15;W=4

80 IF W≧1;D(W)=1:PRINT "Gem";W:IF E+F+G+H=4;PRINT "Ship!":Q=1:M=5

90 IF X=6;X=8

100 IF X=20;Y=6

110 IF X=18;X=15

120 IF X=16;X=18

130 IF X=3;PRINT "Swd!":N=20

140 IF X≠9;RETURN

150 PRINT "◆Happy●End!◆";


P9

10 PRINT "●●MazeLand":VAC:X=5:Y=2:A=1:B=8:GOTO #0

MAZELAND 紹介

■ＭａｚｅＬａｎｄ■

　著作制作…………よなぷー
　制作年月日………２０１６年８月５日
　対応機種…………ＰＢ－１００／１１０／１２０用ゲームプログラム
　使用メモリ………１５６８ステップ
　※「ク」はクラブ、「ス」はスペード、「ハ」はハートの記号です。
　※「●」はスペース一個です。
　※「○」はＥＸＴモードの［ＳＨＩＦＴ］［Ａ］です。
　※「⊂」は［ＡＮＳ］の下の［Ｅ］です。


【　変数表　】

Ａ　　レベル
Ｂ　　体力
Ｃ　　敵体力
Ｄ　　敵攻撃力
Ｅ　　Ｇｅｍ１の有無
Ｆ　　Ｇｅｍ２の有無
Ｇ　　Ｇｅｍ３の有無
Ｈ　　Ｇｅｍ４の有無
Ｉ　　―――
Ｊ　　経験値
Ｋ　　雑魚かボスか
Ｌ＄　今いる場所
Ｍ　　シナリオ進行度
Ｎ　　Ｓｗｄの有無
Ｏ　　―――
Ｐ　　―――
Ｑ　　船の有無
Ｒ＄　河か否か１
Ｓ＄　河か否か２
Ｔ＄　河か否か３
Ｕ＄　河か否か４
Ｖ　　―――
Ｗ　　汎用
Ｘ　　横座標
Ｙ　　縦座標
Ｚ　　―――


【　プログラムエリア表　】

Ｐ０　メインとデータ
Ｐ１　キー入力
Ｐ２　戦闘とボス結果
Ｐ９　初期設定


【　物語　】
　怪物イビルの魔手により、平和だった国は迷路のように作り変えられ、魔物がはびこるようになってしまった。
　あなたはイビルを倒すべく、危険な冒険行へと旅立つのだった。


【　遊び方　】
　［ＳＨＩＦＴ］［９］でスタート、［ＳＨＩＦＴ］［０］でコンティニュー。
　画面は三つに分かれていて、左３マスが南の地形、中央３マスが中央の地形、右３マスが北の地形となっています。［Ｗ］で北、［Ａ］で西、［Ｄ］で東、［Ｘ］で南へ移動できます（ただし行き先が「■」でない場合）。このとき［－］を押すことで今いる地形を調べることができます。「□」は街で体力全回復、「○」はボスとの戦闘、「＃」は魔窟でイビルに挑戦、となります。
　移動中にランダムで敵と出会います。「Ｅｎｅｍｙ：」の後ろに自分の体力が表示されますので、［－］で攻撃、［６］で逃亡（失敗することもあります）します。敵の体力を０にすると経験値が手に入り、経験値が溜まればレベルが上がって攻撃力と最大体力値が上昇します。ボスが相手だった場合は現在地が変わったり、アイテムが手に入ることがあります。
　以上のどの場面でも、［５］で現在の状態を見ることができます。順にレベルと体力、剣の有無、Ｇｅｍの有無となります。
　イビルを倒すか自分の体力が０になるとゲームオーバーです。後者の場合、スタート地点に戻されます（地味につらいので気をつけましょう）。


【　開発後記　】
　「たまには贅沢にメモリを使いたい」と考え、まず１８＊１８のマップありきで作り始めた本作。どうにかギリギリで収拾をつけました。
　クリアするには地図を描いた方がよいと思います。遊びながら描くか、プログラムを参照して描くかはお任せします。

ファイアパンチの現在

無料のWEB漫画雑誌ジャンププラスで連載中の漫画『ファイアパンチ』。

衝撃の第１話に惹かれて未だに読んでいるんだけど、色々下品。

なんか週刊少年チャンピオンで連載していた漫画『覚悟のススメ』を読んだ時と似たような感じがする（あれも下品だった）。

……と、ふと思ったんだが。

なんで焼けた皮膚や肉が足元に落ちないんだろ。

……まあいいか。

扇風機

エアコンなどという文明の利器のない我が家。

頼みの綱は扇風機だけである。

最近は羽根のない扇風機が流行っているが、もちろん我が家のそれは羽根が回転する前時代的な代物だ。

だがやはり涼しい。

あるとないとじゃ大違い。

長く回していると、ガードの部分（正式名称知らん）にゴミが溜まる。

時々ガードを外してティッシュで拭い去る必要があるのだ。

そんな扇風機な毎日……。

TEXT GAME PLAYER ver.5.2c

ゲームブック作成ソフト『TEXT GAME PLAYER』を、バージョン5.2cをもって完結させた。

バグが出なければこれで打ち止め。

正直、終盤はグラフィック関係でプログラムがグチャグチャになり、手の施し用がないほど荒れてしまった。

そこに新たな要素を持ち込むのは困難で、また考えられる機能は大体収録したと判断。

名残惜しいが最終バージョンとした。

ベクターで配信中、よろしゅう。