■Ｈｏｕｓｅ ｏｆ ｔｈｅ ＰＢ■
著作制作…………よなぷー
制作年月日………２０１６年１２月６日
対応機種…………ＰＢ－１００／１１０／１２０用ゲームプログラム
使用メモリ………１５６８ステップ
※「ク」はクラブ、「ス」はスペード、「ハ」はハートの記号です。
※「●」はスペース一個です。
※「○」はＥＸＴモードの［ＳＨＩＦＴ］［Ａ］です。
※「⊂」は［ＡＮＳ］の下の［Ｅ］です。
P0
2 C=0:E=3
4 PRINT CSR0;"Room";A;":";P$(C);:GOSUB #7:IF E≠0 THEN 4
6 IF C≠0;GOSUB 99+A:GOSUB #C:GOTO 2
8 $="↑←↓→Q":E=4:PRINT CSR11;MID(C+1,1);:GOSUB #7:IF E≠0 THEN 8
20 IF C=0;IF A≦5;A=A+3
30 IF C=1;A=A-SGN FRAC(A/3
40 IF C=2;IF A≧3;A=A-3
50 IF C=3;A=A+ABS SGN FRAC((A-2)/3
60 Y=0:GOTO 2
99 $="Safe●●":RETURN
100 $="Statue"+Y$:RETURN
101 $="Rope●●Cutter":RETURN
102 $="Book●●Pen●●●Sofa●●":RETURN
103 $="Vase●●Sofa●●":RETURN
104 $="Match●Table●":RETURN
105 $="Soap●●Towel●Water●":RETURN
106 $="Stove●"+Z$:RETURN
107 $="Bed●●●Pillow":RETURN
P1
10 GOSUB #8:IF C=D;RETURN
20 IF H=10;PRINT "HoleInTheForehead":RETURN
30 IF H=0;PRINT "Dial":RETURN
40 IF H=40;PRINT "Hard&Light":RETURN
50 IF H=70;IF G=0;PRINT "Burning":RETURN
60 IF H=70;IF G=1;PRINT "FireIsOut":RETURN
70 IF H+G=72;PRINT "Cold":RETURN
80 IF H=81;PRINT "Strange":RETURN
90 PRINT "Usually":RETURN
P2
10 GOSUB #8:IF C=D;RETURN
20 IF A≦1 THEN 99
30 IF H=32 THEN 99
40 IF H=41 THEN 99
50 IF H=51 THEN 99
60 IF H=70 THEN 99
70 IF H=71;IF G=0;PRINT "Hot!":RETURN
80 IF H=80 THEN 99
90 IF H=62 THEN 99
95 GOTO #6
99 PRINT "Can'tCarry":RETURN
P3
5 X$="Use:":GOSUB #5:N=C:IF C=3;RETURN
10 GOSUB #8:IF C=D;RETURN
15 $=J$(N):$=MID(1,2):IF H=62;IF $="Va" THEN #4
20 IF H=81;IF $="Cu";F$="Paper●":GOTO #4
25 IF H=70;IF $="Pa";PRINT "Roast","Emerge":F$="Number":GOTO #4
30 IF H=0;IF $="Nu";F$="Jewel●":PRINT "Open":GOTO #4
35 IF H=10;IF $="Je";Y$="Hole●●":PRINT "PutIn","Open"+Y$:RETURN
40 IF H=70;IF $="Wa";PRINT "Extinction":G=1:RETURN
45 IF H=70;IF $="Ma";G=0:PRINT "Ignition":RETURN
50 IF H=11;IF $="Ro";PRINT "GoDown","ZombieDog!":GOTO 60
55 PRINT "Can'tUse":RETURN
60 FOR H=0 TO 2:IF J$(H)=Z$;E=1
65 NEXT H:IF E=0;PRINT "Lose!";:END
70 PRINT "Use";Z$,"BeatTheDog!!","Win!!","ハHappy●End!ハ";
P4
10 PRINT "Get";F$:GOTO #6
P5
4 C=0:E=3
8 PRINT CSR0;X$;J$(C);:GOSUB #7:IF E≠0 THEN 8
20 RETURN
P6
10 X$="Drop:":GOSUB #5:IF C≠3;J$(C)=F$
20 RETURN
P7
9 IF KEY="Q";C=C-SGN C:RETURN
20 IF KEY="W";C=C+SGN(E-C:RETURN
30 IF KEY="6";PRINT:PRINT "■Item",J$,K$,L$:RETURN
40 IF KEY="-";E=0:RETURN
50 GOTO 9
P8
4 $=$+M$:D=LEN($)/6-1:C=0:E=D:PRINT
8 F$=MID(C*6+1,6):PRINT CSR0;F$;:GOSUB #7:IF E≠0 THEN 8
20 H=A*10+C:PRINT:RETURN
P9
10 PRINT "HouseOfThePB":VAC:A=1:P$="Move●":Q$="Check"
20 R$="Take●":S$="Use●●":J$="Empty●":K$=J$:L$=J$
30 M$="Quit●●":Z$="Poker●":GOTO #0
