■ＷＯＮＤＥＲ ＣＡＶＥ■
著作制作…………よなぷー
制作年月日………２０１７年２月６日
対応機種…………ＰＢ－１００／１１０／１２０用ゲームプログラム
使用メモリ………１５６８ステップ
※「ク」はクラブ、「ス」はスペード、「ハ」はハートの記号です。
※「●」はスペース一個です。
※「○」はＥＸＴモードの［ＳＨＩＦＴ］［Ａ］です。
※「⊂」は［ＡＮＳ］の下の［Ｅ］です。
P0
1 C=10*FRAC(1⊂7*LN(B-1:PRINT:IF C>5;PRINT "↓";
2 D=10*FRAC(1⊂7*LN(B-100:IF D>5;PRINT "←";
3 E=10*FRAC(1⊂7*LN(B+100:IF E>5;PRINT "→";
4 F=10*FRAC(1⊂7*LN(B+1:IF F>5;PRINT "↑";
6 PRINT B/100;:IF B=W;PRINT "□";:Q=P↑2+24
7 IF B=X;PRINT "*";:L=A*3+2:M=L↑2*4
8 IF B=Y;PRINT "÷";:IF A>Z;Z=A
9 GOSUB #8:IF K≧2;IF B(K/2)≦5 THEN 9
20 G=K-5:IF ABS G=1;B=B+G*100
25 IF ABS G=3;B=B+SGN G
30 IF K=1;K=0:IF B=X;IF A=Z;D=-1:GOSUB #1:GOTO 1
35 IF RAN#>.3*SGN K THEN 1
40 IF .5>RAN#;L=A*2+INT(RAN#*3:M=L↑2+2:GOSUB #1:GOTO 1
45 $="FAIRYSMITHEVIL!SAGE!LEECH":J=INT(RAN#*5:PRINT
50 PRINT MID(J*5+1,5);"!";:GOSUB #7:IF J=2;L=A*2+3:M=L↑2:GOSUB #1
55 IF J=4;PRINT Q;"●→";:Q=INT(Q*.9:PRINT Q;:GOSUB #7
60 IF J=0;PRINT Q;"●→";:Q=INT(Q*1.1:PRINT Q;:GOSUB #7
65 IF J=3;S=S+SGN(3-S:PRINT "GET●POT!→";S;:GOSUB #7
70 H=0:E=2:$="SWDAMRQIT":IF J≠1 THEN 1
75 J=E↑4*3+48:PRINT MID(H*3+1,3);E;J;:GOSUB #6:IF K=8;E=E+SGN(10-E
80 IF K=2;E=E-SGN(E-2
85 PRINT:IF K≠1 THEN 75
90 IF H=2 THEN 1
95 IF R≧J;IF E>T(H);R=R-J:PRINT "GET!";:T(H)=E:GOSUB #7
100 GOTO 75
P1
3 IF KEY≠"" THEN 3
6 C=1:H=0:$=".onsxmwμ&@ΣΩ$￥ATPTRN≦#≧":IF L=17;L=21:M=2500:C=3
9 PRINT:PRINT MID(L,C);Q;":";MID(H*2+15,2);:GOSUB #6
20 G=T↑2+3+P:E=L↑2-U↑2:IF K≠1 THEN 9
25 PRINT:IF H=2;IF RAN#>.2;PRINT "RUN!";:GOTO #7
30 IF H=1;IF S≧1;PRINT "HEAL!";:S=S-1:Q=P↑2+24:GOSUB #7:H=0:GOTO 9
35 IF H=0;IF RAN#>.05;PRINT "HIT!";G;:GOSUB #7:M=M-G:IF M≦0 THEN 50
40 IF RAN#>.05;IF E≧1;PRINT "DAM!";E;:GOSUB #7:Q=Q-E:IF Q≦0;B=W:END
45 GOTO 9
50 H=2↑L/4+4:PRINT "WIN!+";H;:GOSUB #7:R=R+H:N=N+L↑2
55 IF N≧P↑2;PRINT "LEVEL●UP!!";:N=0:P=P+1:GOSUB #7
60 IF D≧0;RETURN
65 IF A=1;W=5449:X=6763:Y=5662
70 IF A=2;W=5444:X=3132:Y=4248
75 IF A=3;W=1729:X=3263:Y=1946
80 IF A=4;W=5564:X=8385:Y=8288
85 IF A≦4;A=A+1:B=W:RETURN
90 $="●◆TRIUMPH!◆":GOSUB #5
P5
10 FOR H=1 TO 11:FOR G=10 TO H-1 STEP -1
20 PRINT CSRG;MID(H,1);"●";:NEXT G:NEXT H:RETURN
P6
10 GOSUB #8:IF K=4;H=H-SGN H
20 IF K=6;H=H+SGN(2-H
30 RETURN
P7
10 FOR V=0 TO 99:NEXT V:PRINT:RETURN
P8
9 K=0:IF KEY="W";K=8:RETURN
20 IF KEY="A";K=4:RETURN
30 IF KEY="D";K=6:RETURN
40 IF KEY="X";K=2:RETURN
50 IF KEY="-";K=1:RETURN
60 IF KEY≠"6" THEN 9
70 PRINT:PRINT A;"AREA:KEY";Z,P;"L:H";Q,"G";R
80 PRINT T;"S:A";U,"POT";S:RETURN
P9
10 $="WONDER●CAVE":GOSUB #5:STOP:VAC:A=1:W=7827:B=W
20 Y=7749:X=6940:P=1:GOTO #0
