■ＰＢ－１００ ＤＥＭＯ■
著作制作…………よなぷー
制作年月日………２０１７年１１月２１日
対応機種…………ＰＢ－１００／１１０／１２０用ゲームプログラム
使用メモリ………１５６８ステップ
※「ク」はクラブ、「ス」はスペード、「ハ」はハートの記号です。
※「●」はスペース一個です。
※「○」はＥＸＴモードの［ＳＨＩＦＴ］［Ａ］です。
※「⊂」は［ＡＮＳ］の下の［Ｅ］です。
P0
10 $="---*CASIO---":GOSUB #4:$="■◆*PB-100*◆■":GOSUB #4
20 $="-August1982-":GOSUB #4:PRINT "----DEMO----";:GOSUB #2
30 $="_..,oOCASIO*PB-100":FOR A=0 TO 11:FOR B=6 TO A STEP SGN(A-6.5
40 PRINT CSRB;MID(1+ABS(B-6,1);:NEXT B:Z=TAN COS SIN π:PRINT
50 PRINT MID(7,A+1);:NEXT A:GOSUB #1:GOSUB #8:GOSUB #9:GOSUB #7
60 GOSUB #6:GOSUB #5:$="ハPOCKE-COM!ハ":GOSUB #4
70 PRINT "35thAnniversary!";:GOSUB #2:PRINT "スススTHEENDススス";
P1
10 FOR Z=0 TO 70:NEXT Z:RETURN
P2
10 FOR Z=0 TO 400:NEXT Z:PRINT:RETURN
P4
10 FOR A=0 TO 5
20 PRINT CSR5-A;MID(1,A+1);CSR6;MID(12-A,A+1);:NEXT A:GOTO #2
P5
10 $="PB-100*CASIO.,_o○゜'゜○o_πTO■":FOR A=0 TO 11:FOR B=0 TO 14
20 PRINT CSRA;MID(13+B,1);:Z=COS π:NEXT B:PRINT CSRA;MID(A+1,1);
30 NEXT A:GOTO #2
P6
10 GOSUB #2:PRINT "LongLongAgo.";:GOSUB #2:PRINT "TheHuman";
20 GOSUB #2:PRINT "Birthplace.";:GOSUB #2:PRINT "WeCameBack";
30 GOSUB #2:PRINT "There.";:GOSUB #2:E$="'":F$="・":G$=".":H$="■"
40 I$=H$:$="■■■■■■■■■■■■":FOR A=0 TO 3:PRINT CSR0;$;CSRA;"△";
50 GOSUB #1:NEXT A:FOR A=0 TO 40:$=MID(2)+E$(RAN#*5)
60 PRINT CSR0;$;CSR1;"-)△";:NEXT A:$=$+"(●●":FOR A=1 TO 4
70 PRINT CSR0;MID(A,12);CSR3;"△";:GOSUB #1:NEXT A:$=$+"△△△・・・●×"
80 FOR A=4 TO 11:PRINT CSR0;MID(4,12);CSRA;MID(12+A,1);:GOSUB #1
90 NEXT A:$="_._.._..._..":J$="゜":K$="○":L$="o":FOR A=0 TO 29
100 PRINT CSR0;J$(A/10);MID(2,11);:$=MID(2,11)+MID(1,1)
110 NEXT A:FOR A=0 TO 6:PRINT CSR0;$;CSRA;L$;:GOSUB #1:NEXT A:GOSUB #2
120 $="(×)_(×)_/.._._...□":FOR A=1 TO 7:PRINT CSR0;MID(A,12);
130 GOSUB #1:NEXT A:FOR A=2 TO 10:PRINT CSR0;MID(7,12);CSRA;"i";
140 GOSUB #1:NEXT A:GOSUB #2:PRINT "OnTheEarth.";:GOSUB #2
150 PRINT "IPickedItUp.";:GOSUB #2:PRINT "MementoOfThe";:GOSUB #2
160 PRINT "Human.";:GOSUB #2:PRINT "'PB-100'・・・.";:GOSUB #2
170 $="・-○×+*×+*":PRINT "_.._≦□□≧_.._";:FOR A=1 TO 9
180 PRINT CSR5;MID(A,1);CSR6;MID(A,1);:Z=COS TAN SIN π:NEXT A
190 $="_≦≧._△_._゜_._'_._._.":FOR A=0 TO 4:PRINT CSR4;MID(A*4+1,4);
200 GOSUB #1:NEXT A:GOTO #2
P7
10 $="P●C●E●-●A●I●●O●K●T●B●S●C":FOR A=0 TO 11:FOR B=11 TO A STEP -1
20 PRINT CSRB;MID(A+1,1);:NEXT B:NEXT A:FOR A=14 TO 25 STEP 2
30 FOR B=11 TO A-13 STEP -1
40 IF FRAC(B/2≠0;PRINT CSRB;MID(A,1);:Z=COS TAN SIN π
50 NEXT B:NEXT A:GOTO #2
P8
10 FOR A=0 TO 5
20 PRINT CSRA;"×";CSR11-A;"×";CSR SIN COS TAN 0+A;"+";CSR11-A;"+";
30 GOSUB #1:NEXT A:FOR A=0 TO 11:PRINT CSRA;"■";:NEXT A:GOTO #1
P9
10 $="■■-CASIO!-■■":FOR A=1 TO 11:FOR B=A TO 11-A
20 PRINT CSR0;MID(B+1);CSRB;MID(1,12-B);:NEXT B
30 FOR B=A TO 11-A:PRINT CSR0;MID(12-B);CSR11-B;MID(1,B+1);:NEXT B
40 NEXT A:GOTO #2
