バファローズポンタ残留決定！

我らがプロ野球球団・オリックスバファローズのマスコットキャラ『バファローズポンタ』が、来年２０１９年も引き続き応援してくれることが明らかになった。

意味深だった『ＦＡ宣言』は、『ファンと歩む宣言』だったと発覚。

『ファイターズと歩む』でなくて本当に良かった。

勝てば「おりほー！」、負ければ「んほー！」のバファポン、来年こそは前者を連発できるか？

何にしても超極貧打線さえ改善されれば、ＣＳへ行ける地力がつくと思うので、キャンプやオープン戦ではしっかり練習してほしい。

ともあれ、ひとまずホッとしたなあ……

備忘録

Viktor Lazlo - In The Midnight Sky

『夢で逢えたら』のエンディングテーマ。

ウッチャンナンチャン、ダウンタウン、野沢直子、清水ミチコの６人によるコント番組。

懐かし過ぎる(´・∀・｀)

FIGHTS 紹介

■ＦＩＧＨＴＳ■

　著作制作…………よなぷー

　制作年月日………２０１８年１１月２４日

　対応機種…………ＰＢ－１００／１１０／１２０用ゲームプログラム

　使用メモリ………１５６８ステップ

　※「ク」はクラブ、「ス」はスペード、「ハ」はハートの記号です。

　※「●」はスペース一個です。

　※「○」はEXTモードの[SHIFT][A]です。

　※「⊂」は[ANS]の下の[E]です。

【　変数表　】

Ａ　　攻撃側の位置

Ｂ　　敵の行動

Ｃ　　自分の大技値

Ｄ　　敵の　大技値

Ｅ　　技の威力

Ｆ　　ステージ

Ｇ　　自分の位置

Ｈ　　敵の　位置

Ｉ　　自分の技１

Ｊ　　自分の技２

Ｋ　　攻撃側

Ｌ　　最高得点

Ｍ　　自分の技方向

Ｎ　　敵の　技方向

Ｏ＄　最高得点記録者名

Ｐ　　守備側の位置

Ｑ　　攻撃した位置

Ｒ　　汎用

Ｓ　　汎用

Ｔ　　位置判定

Ｕ　　敵の技１

Ｖ　　敵の技２

Ｗ　　自分ガード有無

Ｘ　　敵　ガード有無

Ｙ　　自分の使用中大技

Ｚ　　敵の　使用中大技

【　プログラムエリア表　】

Ｐ０　メイン・タイトル

Ｐ１　小技

Ｐ２　大技

Ｐ３　画面表示

Ｐ４　―――

Ｐ５　飛び道具

Ｐ６　命中判定

Ｐ７　位置チェック・ゲームオーバー

Ｐ８　大技クリア

Ｐ９　時間稼ぎ

【　大技表　】

大技名　　　表示　　威力

　……特徴

閃光弾　　　≠　　　２

　……出ている間動けない

毒霧　　　　ｚ■■　１

　……少し間があく

裏刀　　　　μ÷　　１

　……回り込む

手裏剣　　　＋　　　３

　……出ている間動けない

アッパー　　＆↑　　３

　……一歩前進する

雷撃　　　　’↓　　１

　……少し間があく

龍波動拳　　Ｙ￥　　２

　……間があく

ワープ攻撃　アニメ　１

　……反対側に移動する

閃光連弾　　％％　　１

　……出ている間動けない

爆炎弾　　　△Ｖ　　１

　……少し間があく

【　遊び方　】

　最初にＶＡＣ［ＥＸＥ］を実行して変数を初期化してください。

　［ＳＨＩＦＴ］［０］でゲームスタートです。プレイヤーは「Ω」、敵は「スペード」です。

　［Ｑ］［Ｗ］で小技（前進しつつ２マス攻撃）、ガード（敵の攻撃無効）を繰り出します。［６］［－］で大技（表参照）が出せますが、プレイヤーも敵も、ステージごとに装備される大技がランダムで変化します。何が装備されたかは、出してみるまで分かりません。

　プレイヤーと敵との決定的な違いとして、プレイヤーと敵が重なると、必ずプレイヤー側が押し出される、という点があります。

　敵を押し出すと勝利となり、次のステージに進みます。逆に押し出されると負けとなり、ゲームオーバーとなります。その場合、それまでに倒した人数が得点として表示されます。最高得点を記録していると、７文字までの名前入力が出来ます。

　◎テクニック１「すり抜け」

　　……敵飛び道具をギリギリまで引き付けて、直後に前進することで、当たらずすり抜けることができます。

　◎テクニック２「小技キャンセル」

　　……小技を出した直後に、素早くキーを離し［６］または［－］を押すことで、すぐに大技に移行できます。ちなみに敵も使ってきます。

【　開発後記　】

　おいらの代表作は対戦格闘ゲーム『ＳＴＲＵＧＧＬＥＲＳ　０』ですが、他に違ったアプローチはできないかと考え、今作を完成させました。体力制ではなく押し出し制で、大技も二つ装備し、エンディングもなし（５０人抜きで褒められますが）。なかなか面白いんじゃないかと思います。タイトルはセガのサターン用名作アクション『ＮｉＧＨＴＳ』をもじりました。

　それにしても久々のＰＢ－１００。やっぱりプログラミングは楽しいですね。

FIGHTS プログラム

■ＦＩＧＨＴＳ■

　著作制作…………よなぷー

　制作年月日………２０１８年１１月２４日

　対応機種…………ＰＢ－１００／１１０／１２０用ゲームプログラム

　使用メモリ………１５６８ステップ

　※「ク」はクラブ、「ス」はスペード、「ハ」はハートの記号です。

　※「●」はスペース一個です。

　※「○」はＥＸＴモードの［ＳＨＩＦＴ］［Ａ］です。

　※「⊂」は［ＡＮＳ］の下の［Ｅ］です。

　※Ｐ２の５４行は『”』二つの間に『’』が挟まれています。

P0

4 GOTO 68

8 GOSUB #3:B=INT(RAN#*5-1:IF 0>B;X=0

12 IF G=H;G=G-SGN(5.5-G:C=0:D=0:GOSUB #7:GOTO 8

16 W=1:K=0:A=G:P=H:T=SGN(P-A:IF C≠0;GOSUB #2:GOTO 44

20 R=0:IF KEY="Q";R=T

24 IF KEY="W";R=-T

28 IF R=1;W=0

32 IF 0>R;GOSUB #1

36 IF KEY="-";Y=I:GOSUB #2:GOTO 44

40 IF KEY="6";Y=J:GOSUB #2

44 IF B=9 THEN 72

48 X=1:K=1:A=H:P=G:T=SGN(P-A:IF D≠0;GOSUB #2:GOTO 8

52 IF B≧2;GOSUB #1

56 IF RAN#*SGNB>.7;D=0:Z=U(RAN#*2):GOSUB #2

60 IF B≠9 THEN 8

64 GOTO 72

68 PRINT "●●●FIGHTS","HI";L,"BY●";O$:F=0:$="%≠+゜○o_●"

72 F=F+1:PRINT CSR4;"ST";F;:I=INT(RAN#*10+1:U=INT(RAN#*10+1

76 J=INT(RAN#*10+1:IF I=J THEN 76

80 V=INT(RAN#*10+1:IF U=V THEN 80

84 G=3:H=8:C=0:D=0:GOSUB #9:GOTO 8

P1

10 A=A+T:PRINT CSRA;"○";CSRA+T;"-";:G(K)=A:IF P≠A;IF P≠A+T;RETURN

20 E=1:GOTO #6

P2

1 IF K=1 THEN 6

3 IF C=0;M=T:IF FRAC SQR Y=0;C=A

4 T=M:C=C+T:S=ABS C:Q=A+T:GOTO Y*9

6 IF D=0;N=T:IF FRAC SQR Z=0;D=A

7 T=N:D=D+T:S=ABS D:Q=A+T:IF T≠0 THEN Z*9

8 RETURN

9 E=2:GOTO #5

18 PRINT CSRA;"z";:R=COS π:IF S=1;RETURN

19 PRINT CSRQ;"■";CSRQ+T;"■";:IF P≠Q;IF P≠Q+T THEN #8

20 E=1:GOTO #6

27 FOR R=A TO P+T STEP T:PRINT CSRR;"μ";:NEXT R:IF S=1;G(K)=R-T:GOTO #7

28 PRINT CSRA-T;"÷";:GOSUB #8:T=-T:E=1:IF P=A+T THEN #6

29 RETURN

36 E=3:C(K)=S+T*SGN S:GOTO #5

45 PRINT CSRQ;"&";:IF S=1;G(K)=Q:RETURN

46 PRINT CSRQ;"↑";:E=3:IF Q=P THEN #6

47 GOTO #8

54 IF S=1;M(K)=P:PRINT CSRP;"'";:RETURN

55 PRINT CSRM(K);"↓";:E=1:T=SGN(P-A:IF P=M(K) THEN #6

56 GOTO #8

63 PRINT CSRA;"Y";:E=2:IF S≦2;RETURN

64 FOR R=0 TO 2:IF ABS(A+T-5.5≦5;A=A+T

65 PRINT CSRA;"\";:IF A=P;GOSUB #6:R=2

66 NEXT R:G(K)=A:GOTO #8

72 FOR R=4 TO 8:PRINT CSRA;MID(R,COS 0);:NEXT R:E=1

73 A=ABS(11-A:FOR R=1 TO 5:PRINT CSRA;MID(9-R,COS 0);:NEXT R

74 G(K)=A:GOSUB #3:IF A=P THEN #6

75 GOTO #8

81 E=1:GOSUB #5:S=C(K):IF S≠0;S=S+T:C(K)=S:GOTO #5

82 RETURN

90 PRINT CSRA;"△";:E=COS 0:IF S=1;RETURN

91 FOR S=1 TO 3:R=2*S*T+A:IF ABS(R-5≦5;PRINT CSRR;"V";:IF R=P;GOSUB #6

92 NEXT S:GOTO #8

P3

10 PRINT CSR0;"_●●●●●●●●●●_";CSRG;"Ω";CSRH;"ス";:RETURN

P5

10 PRINT CSRS;MID(E,1);:R=COS π:IF S=P;GOSUB #6

20 IF S≧10 THEN #8

30 RETURN

P6

10 IF W(1-K)=0;PRINT CSRP;"□";:R=COS π:GOTO #8

20 FOR R=1 TO E:PRINT CSRP;"*";:P=P+T*SGN FRAC(P/11

30 NEXT R:G(1-K)=P:B=0:C=0:D=0:GOTO #7

P7

10 IF ABS(H-5.5>5;PRINT CSR4;"WIN!";:B=9:GOTO #9

20 IF ABS(G-5.5≦5;RETURN

30 GOSUB #3:PRINT CSR4;"LOSE";:GOSUB #9:F=F-1

40 PRINT "SC";F;:IF F≧L;L=F:STOP:PRINT "HI!":INPUT "NAME",O$

50 IF F≧50;PRINT "GOD!";

P8

10 C(K)=0:RETURN

P9

10 FOR R=0 TO 150:NEXT R:PRINT:RETURN

FIGHTS

■ＦＩＧＨＴＳ■

　著作制作…………よなぷー

　制作年月日………２０１８年１１月２４日

　対応機種…………ＰＢ－１００／１１０／１２０用ゲームプログラム

　使用メモリ………１５６８ステップ

　※「ク」はクラブ、「ス」はスペード、「ハ」はハートの記号です。

　※「●」はスペース一個です。

　※「○」はEXTモードの[SHIFT][A]です。

　※「⊂」は[ANS]の下の[E]です。

【　変数表　】

Ａ　　攻撃側の位置

Ｂ　　敵の行動

Ｃ　　自分の大技値

Ｄ　　敵の　大技値

Ｅ　　技の威力

Ｆ　　ステージ

Ｇ　　自分の位置

Ｈ　　敵の　位置

Ｉ　　自分の技１

Ｊ　　自分の技２

Ｋ　　攻撃側

Ｌ　　最高得点

Ｍ　　自分の技方向

Ｎ　　敵の　技方向

Ｏ＄　最高得点記録者名

Ｐ　　守備側の位置

Ｑ　　攻撃した位置

Ｒ　　汎用

Ｓ　　汎用

Ｔ　　位置判定

Ｕ　　敵の技１

Ｖ　　敵の技２

Ｗ　　自分ガード有無

Ｘ　　敵　ガード有無

Ｙ　　自分の使用中大技

Ｚ　　敵の　使用中大技

【　プログラムエリア表　】

Ｐ０　メイン・タイトル

Ｐ１　小技

Ｐ２　大技

Ｐ３　画面表示

Ｐ４　―――

Ｐ５　飛び道具

Ｐ６　命中判定

Ｐ７　位置チェック・ゲームオーバー

Ｐ８　大技クリア

Ｐ９　時間稼ぎ

【　大技表　】

大技名　　　表示　　威力

　……特徴

閃光弾　　　≠　　　２

　……出ている間動けない

毒霧　　　　ｚ■■　１

　……少し間があく

裏刀　　　　μ÷　　１

　……回り込む

手裏剣　　　＋　　　３

　……出ている間動けない

アッパー　　＆↑　　３

　……一歩前進する

雷撃　　　　’↓　　１

　……少し間があく

龍波動拳　　Ｙ￥　　２

　……間があく

ワープ攻撃　アニメ　１

　……反対側に移動する

閃光連弾　　％％　　１

　……出ている間動けない

爆炎弾　　　△Ｖ　　１

　……少し間があく

【　遊び方　】

　最初にＶＡＣ［ＥＸＥ］を実行して変数を初期化してください。

　［ＳＨＩＦＴ］［０］でゲームスタートです。プレイヤーは「Ω」、敵は「スペード」です。

　［Ｑ］［Ｗ］で小技（前進しつつ２マス攻撃）、ガード（敵の攻撃無効）を繰り出します。［６］［－］で大技（表参照）が出せますが、プレイヤーも敵も、ステージごとに装備される大技がランダムで変化します。何が装備されたかは、出してみるまで分かりません。

　プレイヤーと敵との決定的な違いとして、プレイヤーと敵が重なると、必ずプレイヤー側が押し出される、という点があります。

　敵を押し出すと勝利となり、次のステージに進みます。逆に押し出されると負けとなり、ゲームオーバーとなります。その場合、それまでに倒した人数が得点として表示されます。最高得点を記録していると、７文字までの名前入力が出来ます。

　◎テクニック１「すり抜け」

　　……敵飛び道具をギリギリまで引き付けて、直後に前進することで、当たらずすり抜けることができます。

　◎テクニック２「小技キャンセル」

　　……小技を出した直後に、素早くキーを離し［６］または［－］を押すことで、すぐに大技に移行できます。ちなみに敵も使ってきます。

【　開発後記　】

　おいらの代表作は対戦格闘ゲーム『ＳＴＲＵＧＧＬＥＲＳ　０』ですが、他に違ったアプローチはできないかと考え、今作を完成させました。体力制ではなく押し出し制で、大技も二つ装備し、エンディングもなし（５０人抜きで褒められますが）。なかなか面白いんじゃないかと思います。タイトルはセガのサターン用名作アクション『ＮｉＧＨＴＳ』をもじりました。

　それにしても久々のＰＢ－１００。やっぱりプログラミングは楽しいですね。