■ＰＢ飯屋■
著作制作…………よなぷー
制作年月日………２０２０年１０月２９日
対応機種…………ＰＢ－１００／１１０／１２０用ゲームプログラム
使用メモリ………１５６８ステップ
※「ク」はクラブ、「ス」はスペード、「ハ」はハートの記号です。
※「●」はスペース一個です。
※「○」はＥＸＴモードの［ＳＨＩＦＴ］［Ａ］です。
※「⊂」は［ＡＮＳ］の下の［Ｅ］です。
P0
1 IF M≦12;PRINT:PRINT M;"M/W";A;:Y=0:GOSUB #7:GOTO 4
2 PRINT "■12M=CLEAR!":IF P≧2⊂4;PRINT "GREAT!"
3 PRINT:PRINT "Kekka";:GOSUB #8:GOTO 3
4 $="SyugyoSendenIchibaSeisouKakcho"
5 PRINT:PRINT MID(Y*6+1,6);:GOSUB #8:IF 0>X;Y=Y-SGN Y
6 IF X=1;Y=Y+SGN(4-Y
7 IF X≠2 THEN 4
8 Q=0:$="YesNo.":PRINT:GOSUB #Y+1:IF Y=5 THEN 1
9 PRINT:PRINT "◆Kaiten!";:GOSUB #7:R=12:K=0
16 PRINT R;":00";:GOSUB #7:H=INT(G/10-L/9+RAN#*4:IF H≦0;H=0
20 IF H≧E;H=E
24 IF H>F;PRINT:PRINT H-F;"Kaeru";:GOSUB #7:H=F
28 PRINT "Kyaku";H;"/";E;:GOSUB #7:IF H=0 THEN 44
32 W=W+1:IF J≦0;GOSUB #6:GOTO 48
36 IF B≧RAN#*16;PRINT "Manzoku!";:G=G+2:GOSUB #7
40 K=K+L*H:J=J-H
44 R=R+3:IF R≦21 THEN 16
48 PRINT "Heiten";:GOSUB #7:PRINT "\+";K;:GOSUB #7
52 P=P+K:IF RAN#≦W/500;PRINT "Chudoku!";:GOSUB #7:W=0:G=G/2
56 A=A+1:IF FRAC(A/5≠0 THEN 1
60 PRINT "Ijihi";-E*50,"Koyou";-F*10:P=P-E*50-F*10:IF P≦0 THEN 99
64 Q=F:A=1:M=M+1
68 PRINT:PRINT "Jugyin";F;"→";Q;:GOSUB #8:IF 0>X;Q=Q-SGN(Q-1
72 IF X=1;Q=Q+SGN(9-Q
76 IF X≠2 THEN 68
80 F=Q:Q=L
84 PRINT:PRINT "Nedan";L;"→";Q;:GOSUB #8:IF 0>X;Q=Q-SGN Q
88 IF X=1;Q=Q+SGN(99-Q
92 IF X≠2 THEN 84
96 L=Q:GOTO 1
99 PRINT "Hasan!";
P1
10 IF J=0 THEN #6
20 J=J-1:PRINT "ExpUP!";:D=D+INT(RAN#*5+5
30 IF D≧B↑2+8;D=0:B=B+1:PRINT "LvUP!";
40 GOTO #7
P2
9 PRINT:PRINT "Senden:\";Q;:GOSUB #8:IF 0>X;Q=Q-5*SGN(Q/5
20 IF X=1;Q=Q+5:IF Q≧100;Q=100
30 IF X≠2 THEN 9
40 IF Q>P THEN #6
50 IF Q=0;Y=5:RETURN
60 P=P-Q:G=G+Q/20+RAN#*5:PRINT:PRINT "Ninki";INT G;:GOTO #7
P3
9 U=1+INT(20+20*FRAC LN(A+π:PRINT:PRINT "Zai:\";U;MID(Q*3+1,3);
20 GOSUB #8:IF ABS X=1;Q=1-Q
30 IF X≠2 THEN 9
40 IF Q=1;Y=5:RETURN
50 IF P≧U;P=P-U:J=J+10:PRINT:PRINT "Get→";J;:Y=5:GOTO #7
60 GOTO 9
P4
10 Q=E*10+10:PRINT:PRINT "Hiyou\";Q;:GOSUB #7:IF Q>P THEN #6
20 P=P-Q:W=0:PRINT "Seiketu!";:GOTO #7
P5
4 IF E=9;PRINT "Max!";:GOTO #7
8 PRINT:PRINT "Hiyou\500";MID(Q*3+1,3);:GOSUB #8:IF ABS X=1;Q=1-Q
20 IF X≠2 THEN 8
30 IF Q=1;Y=5:RETURN
40 IF P≧500;P=P-500:E=E+1:PRINT:PRINT "Kanryo!";E;:GOTO #7
50 GOTO #6
P6
10 PRINT:PRINT "Fusoku!";:Y=5:GOTO #7
P7
10 FOR X=0 TO 140:NEXT X:PRINT:RETURN
P8
9 X=0:IF KEY="Q";X=-1:RETURN
20 IF KEY="W";X=1:RETURN
30 IF KEY="-";X=2:RETURN
40 IF KEY≠"6" THEN 9
50 PRINT:PRINT "Lv";B,"Sozai";J,"Kibo";E,"Fuketu";W,"Ninki";INT G
60 PRINT "Jugyin";F,"Nedan";L,"\";P:RETURN
P9
9 PRINT "PB-Meshiya":VAC:A=1:P=300:B=1:E=2:F=2:L=10:M=1:GOTO #0
