Fx-zardry_readme

========================================================
【  ソフト名   】 Fx-zardry
【 バージョン  】 version 1.0
【 ソフト種別  】 フリーウェア/RPG
【  制作者名   】 よなぷー
【  ファイル名 】 Fx-zardry_ver10.txt
【   対応PC 　 】 CASIO ポケットコンピュータ FX-860P
【   連絡先　  】 [e-mail]
【    転載  　 】 下記参照
【　最終更新   】 2025年12月25日
========================================================

▲◆■　概要　■◆▲
　本作は、著者のプログラム制作３０周年記念作品だった PB-100 用『PIZ』を、FX-860P に移植したものです。ＦＸならではのカタカナ表示を存分に使わせていただきました。


▲◆■　著作権・免責事項　■◆▲
　「Fx-zardry」はフリーソフトです。このソフト（プログラム及び関連ドキュメントを含める）の著作権は、作者であるよなぷーに帰属します。
　ソフト、及び付属テキストは、著作権法および著作権に関する条約をはじめ、その他の無体財産権に関する法律ならびに条約によって保護されています。
　作者に認められている場合を除き、このソフトを第三者に有償で提供することはこれらに違反することになりますのでご注意ください。
　ソフトを使用したことにより生じたいかなる障害、損害において、作者は一切責任を負わないものとします。各自の責任において使用してください。
　また、作者はバグが発見された場合においても、その修正、バージョンアップの義務を負わないものとします。


▲◆■　このソフトの配布、転載に関して　■◆▲
　このプログラム・関連ドキュメントの利益を伴わない再配布、または転載等は基本的に自由とします。雑誌付録への収録なども構いません。その際作者への連絡を必要としません。
　※一切のデータはオリジナルの場合に限ります。


▲◆■　入力方法　■◆▲
　全部で 3379 バイトあります。普通に本体で入力するか、パソコン経由でプログラムを送信してください。
　私の環境は、
・Windows 7 ノートパソコン
・BOOTH の『ac-shop』さんで購入した『CASIO FX-860Pvc 用 USB シリアル変換モジュール（FA-6 相当 IF 版）』
・USB 2.0 ケーブル【A】-【miniB】
・Windows ドライバーに WCH 製の CH340C
・通信ソフトに『PB-1000 Data Communicator32』（『JUN AMANO'S HOMEPAGE』さんより入手）
といった感じです。

●私の送信方法
　まずドライバーと通信ソフトをダウンロードして、あらかじめパソコンに入れておきます。
　次にポケコンへ USB シリアル変換モジュールを接続し、USB ケーブルで繋いで、パソコンの USB 端子にセットします。パソコンにドライバーが入っていれば、初回はそれのインストールが行なわれます。
　続いてポケコンを［ＭＯＤＥ］［１］で BASIC モードにします。そのうえで通信ソフトを立ち上げ、そこに書かれている『PB-1000 Settings:』の後の文字列をポケコンに入力します。たとえば、そのままの設定なら『LOAD"COM0:6,E,8,1,N,N,N,B,N"』となります。
　最後にポケコンのその命令を実行してから、『PB-1000 Data Communicator32』で『Send』を押してテキストファイルを選べば、パソコンからポケコンへプログラムが送信されます。
　逆にポケコンからパソコンへプログラムを送りたい（セーブしたい）なら、『Receive』を押してパソコン側の準備を整えてから、ポケコンで『SAVE"COM0:6,E,8,1,N,N,N,B,N"』を実行します。
　エラーが出てしまう場合は、『Parity』を『None』にしたり『Odd』にしたりしてみてください（私の場合はそれでうまくいきました）。そのときは『SAVE』や『LOAD』の文字列の『E』も変化しますのでご注意を。


▲◆■　物語　■◆▲
　突如森の中に現れた謎の迷宮。そこより発せられる邪悪な空気は、周囲の国々をまたたく間に覆い尽くし、不作や疫病を蔓延させた。苦しみに喘ぐ国々は、迷宮の奥深くに潜む主・デーモンを倒せば災いを逃れられると、６人の冒険者を送り込む。
　彼らは果たして、無事に目的を遂げられるのだろうか……

▲◆■　遊び方　■◆▲
　CAL モードで［ＳＨＩＦＴ］［（入力したプログラムエリア）］と入力するとゲーム開始です。初めて遊ぶ場合は［９］を、続きを遊ぶ場合はそのままで［ＥＸＥ］してください。

　キャンプでは、体力が最大値まで回復し、キャラを転職させることができます。ちなみに順番は関係ありません。

　セ……戦士。最大体力が大幅に上昇。魔法は全然駄目。重たい武器も扱える。
　ト……盗賊。体力は今一つだが器用なため、宝箱の罠を外したり逃げやすくなる。
　ソ……僧侶。体力はそこそこ、魔法も扱える上、体力回復の技能もあるオールラウンダー。
　マ……魔法使い。体力はからきしだが、魔法にかけては右に出るものがいない。
　ニ……忍者。レベル５０より選択可能。クリティカルと器用さに長け、手裏剣を扱える。
　サ……侍。レベル５０より選択可能。僧侶並みの体力とそこそこの魔法。村正を扱える。

　攻撃力や最大体力などの各種能力値は、パーティー各キャラの能力の総計で決まります。
　［Ｑ］［Ｗ］で選択し、［／］で決定、［＊］でキャンセル、［－］で状態表示、が操作の基本です。
　キャンセルでキャンプを出たら迷宮に入ります。迷宮では敵との戦闘が待っています。１０回戦闘に勝つか逃げるかすると、次の階へ進みます。戦闘前に[＊]でキャンセルすると、その階の入り口まで戻ってキャンプします。

　戦闘ではグール、ゴーレムと戦います。グールには物理攻撃のみ、ゴーレムには魔法攻撃のみが通用します。前者はパーティー各キャラが持つ武器の攻撃力を総計した値、後者は魔力の合計値が与えるダメージとなります。
　戦闘は自動で行なわれます。逃げる場合は［Ｑ］を押し続けてください。ただしパーティーの器用さが低いと、必ず逃げられるとは限りません。
　パーティーの体力がなくなるとゲームオーバーです。

　戦闘に勝つと経験値（表示されません）が手に入り、経験値がたまるとレベルアップしてパーティーが強くなります。
　また、必ず宝箱が手に入ります。宝箱は必ず爆弾の罠が仕掛けられており、開ける場合はパーティー全体の器用さ＋運で解除を目指します。うまく罠を外すと武器が、失敗すると爆弾のダメージが与えられます。武器を獲得できた場合は、［／］で装備するか、［＊］でキャンセルして捨てるかしてください。
　武器は数値が大きいほど威力も高くなります。ただし、キャラの職業によって扱える武器に制限があります。

　・素手……何もなし。転職するとこれになる。
　・木の杖……全員可。
　・棍棒……全員可。
　・魔の杖……全員可。
　・剣……戦士・盗賊・忍者・侍のみ使用可。
　・長剣……戦士・盗賊・忍者・侍のみ使用可。
　・斧……戦士・侍のみ使用可。
　・カシナート（の剣）……戦士・侍のみ使用可。
　・手裏剣……忍者のみ使用可。
　・村正……最強の武器、侍のみ。

　戦闘に勝つと、僧侶の人数に応じて体力がじゃっかん回復します。

　以上のほとんどの場面において、［－］でパーティーの状態を表示できます。まずはそれぞれのキャラの職業と武器が、それに続いて順に体力と最大体力、レベル、物理攻撃力、魔法攻撃力、体力回復力、器用さ、クリティカル（一撃必殺）率、と表示されます。

　迷宮は全部で５０階あり、５０階にはデーモンが待っています。デーモンには物理攻撃しか効かず、また逃げることもできません。勝つとクリア、負けるとゲームオーバーとなりますが、いずれの場合でも４５階に戻されます。


▲◆■　変数表　■◆▲
Ａ　　パーティー体力　　　　　　　Ｎ　　パーティー回復力
Ｂ　　パーティー最大体力          Ｏ＄　パーティー姿
Ｃ　　パーティー器用度            Ｐ　　現在地
Ｄ　　パーティークリティカル率    Ｑ　　汎用
Ｅ　　汎用                        Ｒ　　キー入力
Ｆ　　敵の種類                    Ｓ　　カーソル位置
Ｇ　　敵の体力                    Ｔ　　汎用
Ｈ　　入手した武器の威力          Ｕ（１～６）装備武器
Ｉ　　到達階                      Ｖ　　―――
Ｊ　　パーティー経験値            Ｗ（１～６）各キャラ職業
Ｋ　　パーティーレベル            Ｘ　　汎用
Ｌ　　パーティー攻撃力            Ｙ　　時間稼ぎ
Ｍ　　パーティー魔法攻撃力        Ｚ＄　職業正式名


▲◆■　バージョン　■◆▲
　1.0……ひとまず完成


▲◆■　開発後記　■◆▲
　深い階に潜らないとろくな武器が出ないので、盗賊を使って『Ｑボタン押しっ放し連続逃亡』をすると楽に先へ進めるでしょう。あまり楽しても、レベルが足りなくて詰んでしまうこともあるので、僧侶二段構えで経験値稼ぎに腐心するのも忘れずに。
　なお、階の進行中にレベルアップしても、次にキャンプを開くまでは物理・魔法ともどもそれが反映されません。これは仕様です（ひどい言い訳）。
　しかしまあ、やっぱりこのゲームは面白いですね。カタカナ表記で見やすくなったし、ついつい自画自賛してしまいます。FX-860P ユーザーの方は、ぜひとも遊びましょう。

Fx-zardry_ver10

10 '=FX-ZARDRY= VER.1.0 BY YONAPUU,2025

20 GOSUB 750

30 'ﾒｲﾝ

40 CLS:PRINT "ｷｬﾝﾌﾟ:ﾃﾝｼｮｸ";:GOSUB 730

50 GOSUB 390:A=B:P=I:IF R<>3 THEN 50

60 CLS:PRINT O$;":";P;:GOSUB 540:IF R=4 THEN 60

70 IF R=3 THEN 40

80 F=INT(RAN#*2):G=I^2+8:IF P=50 THEN F=2:G=2E4:I=45

90 CLS:LOCATE 0,0:PRINT O$;MID$(F*6+7,6);:GOSUB 730

100 IF INKEY$="Q" THEN IF C+.3>=RAN# THEN IF F<>2 THEN CLS:PRINT "ﾆｹﾞﾀﾞｼﾀ!";:GOSUB 730:GOTO 270

110 IF RAN#>=.7 THEN S=I*5+2:LOCATE 0,0:PRINT "*";S;:A=A-S:GOSUB 360:GOSUB 730:GOTO 90

120 S=SGN FRAC(F/2):X=M:IF S=0 THEN X=L

130 LOCATE 7,0:PRINT INT X;:G=G-X:GOSUB 730:IF RAN#+S<=D THEN PRINT "ｸﾘﾃｨｶﾙ!";:G=0:GOSUB 730

140 IF G>=1 THEN 90

150 CLS:PRINT "ｼｮｳﾘ!";:J=J+I^2+1:GOSUB 730:IF J>=K^2 THEN J=0:K=K+1:PRINT "ﾚﾍﾞﾙｱｯﾌﾟ!";:GOSUB 730

160 IF N>0 THEN A=INT(A+B*N):PRINT "ﾀｲﾘｮｸ+";INT(B*N);:GOSUB 730:IF A>=B THEN A=B

170 CLS:PRINT "ﾀｶﾗﾊﾞｺ:ｱｹﾙ>[/]";:GOSUB 540:IF R=4 THEN 170

180 IF R<>2 THEN 270

190 H=1+.1*INT(2*RAN#*RAN#*P):IF H>=10 THEN H=9.9

200 IF C+.35=<RAN# THEN CLS:PRINT "ﾊﾞｸﾊﾂｼﾀ!";I*8+2;:A=A-I*8-2:GOSUB 730:GOSUB 360:GOTO 270

210 CLS:PRINT "GET!";MID$(INT H*5+25,5);H;:GOSUB 540:IF R=4 THEN 210

220 IF R=3 THEN 270

230 GOSUB 480:Q=S+1:IF R<>2 THEN 210 ELSE GOSUB 450

240 GOSUB 540:IF R=3 THEN 210

250 IF R=2 THEN GOSUB 300

260 IF R<>3 THEN 210

270 P=P+.1:IF FRAC P=0 THEN CLS:PRINT P-1;"ｶｲ:ｸﾘｱ-!";:GOSUB 730:I=P

280 IF F<>2 THEN 60

290 CLS:PRINT "ｱﾅﾀﾀﾁﾊ ﾃﾞ-ﾓﾝｦ ﾀｵｼ,ｽﾍﾞﾃﾉ ｵｳｺｸｦ ｽｸｯﾀ!!","ｵﾒﾃﾞﾄｳ!","ﾊｯﾋﾟ-ｴﾝﾄﾞ!";:END

300 E=W(Q-1):IF H>=4 THEN IF ABS(E-2.5)<1 THEN RETURN

310 IF H>=6 THEN IF H<8 THEN IF ABS(E-2.5)<2 THEN RETURN

320 IF INT H=8 THEN IF E<>4 THEN RETURN

330 IF INT H=9 THEN IF E<>5 THEN RETURN

340 CLS:PRINT "ｿｳﾋﾞｼﾀ!";:U(Q)=H:R=3:T=1:GOSUB 730:GOTO 630

350 'ｼﾎﾞｳﾊﾝﾃｲ

360 IF A>=1 THEN RETURN

370 PRINT "ｹﾞ-ﾑ ｵ-ﾊﾞ-";:END

380 'ｷｬﾝﾌﾟ(ﾃﾝｼｮｸ ｼｮﾘ)

390 GOSUB 480:IF R<>2 THEN RETURN

400 Q=S+1:GOSUB 450:S=1:G=4:IF K>=50 THEN G=6

410 LOCATE 15,0:PRINT "<";MID$(Z$,S*5-4,5);:GOSUB 540:IF R=<1 THEN S=1+S*SGN(G-S):GOTO 410

420 IF R<>2 THEN RETURN

430 CLS:PRINT "ﾃﾝｼｮｸｼﾀ!";:U(Q)=0:W(Q-1)=S-1:GOSUB 730:RETURN

440 'ｿｳﾋﾞﾋｮｳｼﾞ

450 CLS:PRINT Q;":";MID$(W(Q-1)+1,1);"_";

460 PRINT MID$(INT U(Q)*5+25,5);U(Q);:RETURN

470 'ｶｰｿﾙｲﾄﾞｳ

480 S=2

490 T=2:GOSUB 630:LOCATE S*2+1,0:PRINT "<";:GOSUB 540:IF R=4 THEN 490

500 IF 0>R THEN S=S-SGN S:GOTO 490

510 IF R=1 THEN S=S+SGN(5-S):GOTO 490

520 RETURN

530 'ｷｰﾆｭｳﾘｮｸ & ｼﾞｮｳﾀｲﾋｮｳｼﾞ

540 K$=INKEY$:IF K$="Q" THEN R=-1:RETURN

550 IF K$="W" THEN R=1:RETURN

560 IF K$="/" THEN R=2:RETURN

570 IF K$="*" THEN R=3:RETURN

580 IF K$<>"-" THEN 540

590 FOR Q=1 TO 6:GOSUB 450:STOP:NEXT Q:R=4

600 CLS:PRINT "ﾚﾍﾞﾙ";K;":ﾀｲﾘｮｸ";A;"/";B,"ﾌﾞﾂﾘ";INTL;":ﾏﾎｳ";M,"ｶｲﾌｸﾘｮｸ";N

610 PRINT "ｷﾖｳｻ";C;":ｸﾘﾃｨｶﾙ";D:RETURN

620 'ﾊﾟｰﾃｨ-ﾉｳﾘｮｸﾁｪｯｸ

630 CLS:B=0:N=0:L=0:M=0:C=0:D=0:O$="":FOR Q=0 TO 5:E=W(Q)

640 L=L+U(Q)^3+K:ON E+1 GOSUB 660,670,680,690,700,710:G$=MID$(E+1,1):LOCATE Q*T,0:PRINT G$;

650 O$=O$+G$:NEXT Q:RETURN

660 B=B+K*5:RETURN

670 B=B+K:C=C+.6:RETURN

680 B=B+K*3:M=M+K*2:N=N+.2:RETURN

690 M=M+K*5:RETURN

700 B=B+K:D=D+.05:C=C+.4:RETURN

710 B=B+K*3:M=M+K:RETURN

720 'ｼﾞｶﾝｶｾｷﾞ

730 FOR Y=0 TO 120:NEXT Y:RETURN

740 'ｻｲｼｮ

750 INPUT "9=ｻｲｼｮｶﾗ,ﾎｶ=ﾂﾂﾞｷｶﾗ",Q$:IF Q$<>"9" THEN 40

760 'ﾀｲﾄﾙ

770 CLS:PRINT "*FX-ZARDRY*":CLEAR:DIM U(6):DIM W(6):K=1

780 $="ｾﾄｿﾏﾆｻ:ｸﾞ-ﾙ :ｺﾞ-ﾚﾑ:ﾃﾞ-ﾓﾝｽﾃﾞ  ｷﾉﾂｴ ｺﾝﾎﾞｳﾏﾎﾉﾂｴｹﾝ   ﾁｮｳｹﾝｵﾉ   ｶｼﾅ-ﾄｼｭﾘｹﾝﾑﾗﾏｻ "

790 Z$="ｾﾝｼ  ﾄｳｿﾞｸｿｳﾘｮ ﾏﾎﾂｶｲﾆﾝｼﾞｬｻﾑﾗｲ "

800 GOTO 40

Moonlit_Castle_readme

========================================================

【  ソフト名   】 Moonlit_Castle

【 バージョン  】 version 1.1

【 ソフト種別  】 フリーウェア/RPG

【  制作者名   】 よなぷー

【  ファイル名 】 Moonlit_Castle_ver11.txt

【   対応PC 　 】 FX-860P シリーズ

【   連絡先　  】 [e-mail]

【    転載  　 】 下記参照

【　最終更新   】 2025年 5月17日

========================================================

▲◆■　概要　■◆▲

　PB-100 で作った拙作『COLLAPSE ver.2』を FX-860P シリーズに移植してみました。迷宮探検型のロールプレイングゲームです。

▲◆■　著作権・免責事項　■◆▲

　「Moonlit_Castle」はフリーソフトです。このソフト（プログラム及び関連ドキュメントを含める）の著作権は、作者であるよなぷーに帰属します。

　ソフト、及び付属テキストは、著作権法および著作権に関する条約をはじめ、その他の無体財産権に関する法律ならびに条約によって保護されています。

　作者に認められている場合を除き、このソフトを第三者に有償で提供することはこれらに違反することになりますのでご注意ください。

　ソフトを使用したことにより生じたいかなる障害、損害において、作者は一切責任を負わないものとします。各自の責任において使用してください。

　また、作者はバグが発見された場合においても、その修正、バージョンアップの義務を負わないものとします。

▲◆■　このソフトの配布、転載に関して　■◆▲

　このプログラム・関連ドキュメントの利益を伴わない再配布、または転載等は基本的に自由とします。雑誌付録への収録なども構いません。その際作者への連絡を必要としません。

　※一切のデータはオリジナルの場合に限ります。

▲◆■　入力方法　■◆▲

　全部で6976バイトあります。普通に本体で入力するか、パソコン経由でプログラムを送信してください。

　私の環境は、

・Windows 7 ノートパソコン

・BOOTH の『ac-shop』さんで購入した『CASIO FX-860Pvc 用 USB シリアル変換モジュール（FA-6 相当 IF 版）』

・USB 2.0 ケーブル【A】-【miniB】

・Windows ドライバーに WCH 製の CH340C

・通信ソフトに『PB-1000 Data Communicator32』（『JUN AMANO'S HOMEPAGE』さんより入手）

といった感じです。

●私の送信方法

　まずドライバーと通信ソフトをダウンロードして、あらかじめパソコンに入れておきます。

　次にポケコンへ USB シリアル変換モジュールを接続し、USB ケーブルで繋いで、パソコンの USB 端子にセットします。パソコンにドライバーが入っていれば、初回はそれのインストールが行なわれます。

　続いてポケコンを［ＭＯＤＥ］［１］で BASIC モードにします。そのうえで通信ソフトを立ち上げ、そこに書かれている『PB-1000 Settings:』の後の文字列をポケコンに入力します。たとえば、そのままの設定なら『LOAD"COM0:6,E,8,1,N,N,N,B,N"』となります。

　最後にポケコンのその命令を実行してから、『PB-1000 Data Communicator32』で『Send』を押してテキストファイルを選べば、パソコンからポケコンへプログラムが送信されます。なお、リストの最後は必ず空白行を付けておいてください。

　逆にポケコンからパソコンへプログラムを送りたい（セーブしたい）なら、『Receive』を押してパソコン側の準備を整えてから、ポケコンで『SAVE"COM0:6,E,8,1,N,N,N,B,N"』を実行します。

　エラーが出てしまう場合は、『Parity』を『None』にしたり『Odd』にしたりしてみてください（私の場合はそれでうまくいきました）。そのときは『SAVE』や『LOAD』の文字列の『E』も変化しますのでご注意を。

▲◆■　遊び方　■◆▲

　CAL モードで［ＳＨＩＦＴ］［（入力したプログラムエリア）］と入力するとゲーム開始です。初めて遊ぶ場合は［９］を、続きを遊ぶ場合はそのままで［ＥＸＥ］してください。

　画面左上に３マスの迷宮画像、プレイヤーの横座標．縦座標、向いている方向が表示されます。［Ｑ］［Ｗ］で左右を、［Ａ］で背後を向き、［／］で一歩前進します。枕（Pillow）があれば、［＊］でキャンプもできます（体力が若干回復）。

　その階のスタート地点には『△』があり、『NX』で示される経験値を貯めていればレベルが上がります（体力の最大値が増加）。『○』は枕保管所で、キャンプに必要な枕が９までチャージされます。『↑』は次の階へのはしごであり、ボスである天使との戦闘となります。倒せば次の階に進みます。

　ちなみに迷宮は各階９×９のブロックで構成されており、全１５フロアとなっております。

　前進すると、運がよければ剣を発見します。剣の威力が表示されるので、装備する（GET）か捨てる（Throw）か、［Ｑ］［Ｗ］で選択し［／］で決定してください。剣の耐久度（EN）は８～１７の範囲となります。

　また、敵に遭遇することもあります。戦う（FIGHT）か研磨剤を使う（Abrasive）か、それとも逃げる（RUN）か、［Ｑ］［Ｗ］で選択し［／］で決定してください。ちなみに研磨剤は持っていなければ当然使えません。また、逃走は失敗することもあります。

　戦うを選択した場合、敵を攻撃（HIT）しますが、そのたびに剣の耐久度は１減ってしまいます。これが０になると壊れてダメージを与えられなくなります。研磨剤を使うと耐久度は１０に回復します。

　敵の体力を０にすると経験値が手に入り、運がよければ研磨剤も入手できます（１個しか持ち歩けません）。

　以上のどの場面でも、［６］でプレイヤーの状態が表示されます。順に階数、レベル、体力、経験値、剣の威力と耐久度、研磨剤の有無、枕の数、となります。

　１５階の堕天使を倒すか、体力が０になるとゲームオーバーです。前者の場合はエンディングとなり、後者の場合は経験値を半分にされてスタート地点に戻されます。

▲◆■　変数表　■◆▲

Ａ　　汎用                Ｎ　　汎用

Ｂ　　キー入力         Ｏ　　―――

Ｃ　　データ文字列  Ｐ　　レベル

Ｄ　　スタート地点  Ｑ　　体力

Ｅ　　汎用                Ｒ　　剣の威力

Ｆ　　階段位置         Ｓ　　剣の耐久度

Ｇ　　向き                Ｔ　　経験値

Ｈ　　階                   Ｕ　　敵の攻撃力

Ｉ　　枕の数            Ｖ　　汎用

Ｊ　　汎用                Ｗ　　研磨剤の有無

Ｋ　　迷宮用            Ｘ　　汎用

Ｌ　　敵の種類         Ｙ　　汎用

Ｍ　　敵の体力         Ｚ　　現在地

▲◆■　開発後記　■◆▲

　ついに FX-860P シリーズ第一作を完成させました。ここにいたるまで長かった……。迷宮移動は遅いし、移植作品ではありますが、そこらへんはご勘弁を。

　それにしても、グラフィック文字やカタカナが使えると、普通なゲームもより良く映えますね。次は何を作ろうかな。

　まあ楽しんでください。

　Version 1.1……迷宮移動の高速化を行ないました。

タグ ：

#FX-860P

#CASIO

#RPG

#ゲーム

#プログラム

Moonlit_Castle_ver11

10 '=MOONLIT CASTLE= VER.1.1 BY YONAPUU,2023-2025

20 GOTO 1130

30 'ﾒｲﾛ ｺｳﾁｸ

40 Y=0:IF X<1 THEN 90

50 E=FRAC(1E6*LN(H*X)):IF E>.7 THEN Y=1:IF E>.95 THEN Y=2

60 IF X=D THEN Y=3

70 IF X=F THEN Y=4

80 IF X>=11 AND X<=99 AND FRAC(X/10)<>0 THEN 100

90 Y=1

100 AA=Y:RETURN

110 'ｷ-ﾆｭｳﾘｮｸ

120 B$=INKEY$:IF B$="Q" THEN B=0:RETURN

130 IF B$="W" THEN B=1:RETURN

140 IF B$="/" THEN B=8:RETURN

150 IF B$="*" THEN B=2:RETURN

160 IF B$="A" THEN B=4:RETURN

170 IF B$<>"6" THEN 120

180 LOCATE 9,0:PRINT H;"FL:LV";P:LOCATE 9,0:PRINT Q;"HP:EX";T

190 LOCATE 9,0:PRINT R;"SW:EN";S;" ":LOCATE 9,0:PRINT W;"ABR:P";I;" ";

200 B=3:GOTO 1080

210 'ﾒｲﾛ ﾋｮｳｼﾞ

220 CLS

230 IF P3>0 THEN PRINT MID$(C$,P3+4,1);:GOTO 250

240 IF P4>0 THEN PRINT MID$(C$,P4+8,1);

250 PRINT TAB(1);:IF P1>0 THEN PRINT MID$(C$,P1+8,1);:GOTO 270

260 IF P2>0 THEN PRINT CHR$(165);

270 PRINT TAB(2);:IF P5>0 THEN PRINT MID$(C$,P5+12,1);:GOTO 290

280 IF P6>0 THEN PRINT MID$(C$,P6+8,1);

290 PRINT TAB(3);Z/10;MID$(C$,G,1);

300 GOSUB 120

310 IF B<>1 THEN 390

320 'ﾐｷﾞｦ ﾑｸ

330 G=G-1:IF G<1 THEN G=4

340 P3=P1:P4=P6:P1=P5

350 IF G=1 THEN X=Z+10:GOSUB 40:P5=AA:X=Z+9:GOSUB 40:P6=AA:IF P1<>1 THEN X=Z-2:GOSUB 40:P2=AA

360 IF G=2 THEN X=Z-1:GOSUB 40:P5=AA:X=Z-11:GOSUB 40:P6=AA:IF P1<>1 THEN X=Z-20:GOSUB 40:P2=AA

370 IF G=3 THEN X=Z-10:GOSUB 40:P5=AA:X=Z-9:GOSUB 40:P6=AA:IF P1<>1 THEN X=Z+2:GOSUB 40:P2=AA

380 IF G=4 THEN X=Z+1:GOSUB 40:P5=AA:X=Z+11:GOSUB 40:P6=AA:IF P1<>1 THEN X=Z+20:GOSUB 40:P2=AA

390 IF B<>0 THEN 470

400 'ﾋﾀﾞﾘｦ ﾑｸ

410 G=G+1:IF G>4 THEN G=1

420 P5=P1:P6=P4:P1=P3

430 IF G=1 THEN X=Z-10:GOSUB 40:P3=AA:X=Z-11:GOSUB 40:P4=AA:IF P1<>1 THEN X=Z-2:GOSUB 40:P2=AA

440 IF G=2 THEN X=Z+1:GOSUB 40:P3=AA:X=Z-9:GOSUB 40:P4=AA:IF P1<>1 THEN X=Z-20:GOSUB 40:P2=AA

450 IF G=3 THEN X=Z+10:GOSUB 40:P3=AA:X=Z+11:GOSUB 40:P4=AA:IF P1<>1 THEN X=Z+2:GOSUB 40:P2=AA

460 IF G=4 THEN X=Z-1:GOSUB 40:P3=AA:X=Z+9:GOSUB 40:P4=AA:IF P1<>1 THEN X=Z+20:GOSUB 40:P2=AA

470 IF B<>8 OR P1=1 THEN 560

480 'ｾﾞﾝｼﾝ

490 Z=Z-(G=4)*10-(G=3)+(G=2)*10+(G=1)

500 C=P1+1:P3=P4:P1=P2:P5=P6 

510 IF G=1 THEN X=Z-11:GOSUB 40:P4=AA:X=Z+9:GOSUB 40:P6=AA:IF P1<>1 THEN X=Z-2:GOSUB 40:P2=AA

520 IF G=2 THEN X=Z-9:GOSUB 40:P4=AA:X=Z-11:GOSUB 40:P6=AA:IF P1<>1 THEN X=Z-20:GOSUB 40:P2=AA

530 IF G=3 THEN X=Z+11:GOSUB 40:P4=AA:X=Z-9:GOSUB 40:P6=AA:IF P1<>1 THEN X=Z+2:GOSUB 40:P2=AA

540 IF G=4 THEN X=Z+9:GOSUB 40:P4=AA:X=Z+11:GOSUB 40:P6=AA:IF P1<>1 THEN X=Z+20:GOSUB 40:P2=AA

550 ON C GOTO 620,220,660,680,710

560 IF B=4 THEN G=G-2:IF G<1 THEN G=4+G

570 IF B=4 THEN 1380

580 IF B=2 AND I>0 THEN 1050

590 IF B=8 AND P1=1 THEN 300

600 GOTO 220

610 'ﾃﾞｸﾜｽ ﾓﾉ

620 IF RAN#<.3 THEN GOSUB 730

630 IF RAN#>.3 THEN 220

640 L=H+INT(RAN#*2:M=L^2+5:U=3*L+2:PRINT "ENEMY!";:GOSUB 800:GOTO 220

650 'ﾏｸﾗ ｹﾞｯﾄ

660 PRINT "GET PLW";:I=9:GOSUB 1080:GOTO 220

670 'ﾚﾍﾞﾙ ｱｯﾌﾟ?

680 E=(P+2)^2:PRINT "NX";E;:GOSUB 1080:IF T<E THEN 220

690 PRINT "LV UP!";:P=P+1:T=0:GOSUB 1080:GOTO 220

700 'ﾃﾝｼ ｼｭﾂｹﾞﾝ

710 PRINT "ANGEL!";:M=H^2*6+20:U=8+INT(H^2/3:L=1:Y=8:GOSUB 800:GOTO 220

720 'ﾂﾙｷﾞ ｹﾞｯﾄ

730 E=INT(RAN#*H^2+3:J=1:PRINT "FIND SW";

740 LOCATE 0,1:PRINT E;"SW:";MID$(C$,17+3*J,3);

750 GOSUB 120:IF B=0 THEN J=0 ELSE IF B=1 THEN J=1

760 IF B<>8 THEN 740

770 IF J=0 THEN PRINT ":EQUIP!";:R=E:S=INT(10*RAN#+8)

780 GOSUB 1080:RETURN

790 'ﾃｷ ｽｶﾞﾀｦ ﾛ-ﾄﾞ

800 N=0:RESTORE INT((L-1)/2)*10+1060:READ N$:IF FRAC(L/2)=0 THEN READ N$

810 DEFCHR$(252)=N$:IF Y=8 THEN DEFCHR$(252)="70183E1870"

820 LOCATE 1,0:IF Y<8 OR H<15 THEN PRINT CHR$(252);:GOTO 870

830 RESTORE 1310:LOCATE 0,0:FOR X=0 TO 2:READ N$:DEFCHR$(252+X)=N$:PRINT CHR$(252+X);:NEXT:M=1500

840 LOCATE 9,0:PRINT "ﾊﾞｶﾒ,ｲﾏｻﾗ ﾆﾝｹﾞﾝｺﾞﾄｷｶﾞ ﾅﾝﾉﾖｳﾀﾞ.":GOSUB 1100:PRINT "ﾜﾀｼﾉ ﾏﾈｲﾀ ﾒﾂﾎﾞｳﾏﾃﾞ ｱﾄ ｽｺｼ...":GOSUB 1100

850 PRINT "ﾋﾏﾂﾌﾞｼｶ ｳｻﾊﾗｼｶ?":GOSUB 1100:PRINT "ｲｲﾀﾞﾛｳ,ｳｹﾃﾀｯﾃﾔﾙ!":GOSUB 1100

860 'ｾﾝﾄｳﾒｲﾝ

870 LOCATE 0,1:PRINT MID$(C$,23+N*5,5);:LOCATE 9,0:GOSUB 120

880 IF B=0 THEN N=N-SGN N

890 IF B=1 THEN N=N+SGN(2-N

900 IF B<>8 THEN 870

910 X=SGN S*(R+INT(RAN#*R)):IF N+RAN#>2.2 THEN GOSUB 1080:PRINT "RUN!";:GOTO 1080

920 S=S-SGN S:IF N*W=1 THEN PRINT "USE ABR";:W=0:N=0:S=10:GOTO 870

930 PRINT "HIT";X;:IF S=0 THEN PRINT ":SW BREAK";:GOSUB 1080

940 M=M-X:X=U-INT(RAN#*U:IF M<1 THEN 970

950 PRINT "DAM!";X;:Q=Q-X:GOSUB 1080:IF Q>0 THEN 870

960 Z=D:Q=48:T=INT(T/2):LOCATE 0,1:PRINT "LOSE";:GOSUB 1080:END

970 LOCATE 0,1:PRINT "WIN!!";:T=T+U:IF RAN#>.8 THEN PRINT ":ABR!";:W=1

980 GOSUB 1080:IF Y<>8 THEN RETURN

990 H=H+1:IF H<16 THEN D=F:F=INT(11+89*FRAC(TAN H*1E7:RETURN

1000 'ｵｼﾏｲ

1010 H=15:STOP:CLS:RESTORE 1340:FOR B=1 TO 6:READ N$:E=LEN(N$):FOR A=1 TO E

1020 J$=MID$(N$,A,1):IF J$="A" THEN J$=CHR$(224) ELSE IF J$="B" THEN J$=CHR$(225)

1030 J$=CHR$(ASC(J$)-3):PRINT J$;:NEXT:STOP:CLS:NEXT:END

1040 'ｷｬﾝﾌﾟ

1050 I=I-1:E=48+INT(P^2/3):Q=Q+INT(E/5):IF Q>E THEN Q=E

1060 PRINT "CAMP";Q;:GOSUB 1080:GOTO 630

1070 'ｼﾞｶﾝｶｾｷﾞ

1080 FOR V=0 TO 200:NEXT

1090 'ﾌﾞﾝｼｮｳ ｸﾘｱ

1100 LOCATE 9,0:PRINT "                       ";

1110 LOCATE 0,1:PRINT "                                ";:LOCATE 9,0:RETURN

1120 'ｹﾞ-ﾑ ｶｲｼ

1130 C=0:INPUT "9=ｻｲｼｮｶﾗ,ﾎｶ=ﾂﾂﾞｷｶﾗ",N$:IF N$<>"9" THEN 1380

1140 RESTORE 1320:FOR X=0 TO 3:READ C$:DEFCHR$(252+X)=C$:NEXT:CLS:PRINT CHR$(252);CHR$(135);CHR$(135);

1150 PRINT TAB(0);CHR$(253);CHR$(254);CHR$(255);" MOONLIT CASTLE"

1160 PRINT "ｶﾐﾄ ﾀﾀｶｲ ﾔﾌﾞﾚﾀ ﾀﾞﾃﾝｼﾊ","ｻｲｺﾞﾉ ﾃｲｺｳﾄ ｼﾃ,ﾁｷｭｳﾆ ｲﾝｾｷﾉ ｱﾒｦ ﾌﾗｾﾙｺﾄﾆｼﾀ."

1170 PRINT "ｶﾐﾉ ﾂｸﾘｼ ﾆﾝｹﾞﾝﾀﾁｦ ﾐﾁﾂﾞﾚﾆ ｽﾙﾀﾒﾀﾞ.","ｻｲﾊ ﾅｹﾞﾗﾚ,ﾓﾊﾔ ﾁｷｭｳﾒﾂﾎﾞｳｦ ﾄﾒﾙ ｽﾍﾞﾊ ﾅｲ."

1180 PRINT "ﾎﾛﾋﾞﾕｸ ｾｶｲﾃﾞ,ｱﾅﾀﾊ ｹﾞﾝｷｮｳﾉ ﾀﾞﾃﾝｼﾆ ﾌｸｼｭｳｼﾖｳﾄｽﾙ.","ｿﾚｶﾞ ｲﾏﾔ ﾏｯﾀｸ ｵﾛｶﾅｺｳｲﾃﾞ ｱﾙﾄ,ﾑｴｷﾃﾞ ﾑｶﾁﾅﾀﾀｶｲﾃﾞ ｱﾙﾄ ｼﾘﾅｶﾞﾗ..."

1190 CLEAR:G=4:H=1:Z=55:C$=CHR$(227)+CHR$(228)+CHR$(229)+CHR$(230):DEFCHR$(255)="00FEFEFE00"

1200 C$=C$+"])>I"+CHR$(236)+CHR$(237)+CHR$(238)+CHR$(227)+"[(<I"

1210 C$=C$+"GETTRWFIGHTABR  RUN  ":R=3:S=10:Z=99:D=Z:Q=48:P=1:F=15:GOTO 1450

1220 'ﾃｷﾉ ｽｶﾞﾀ ﾃﾞ-ﾀ

1230 DATA060E0E0A06,7820702078

1240 DATAF0307E2C00,20B678B620

1250 DATAE214381462,0042720E02

1260 DATAAC703070AC,08107E3C30

1270 DATA18F27CF218,6076F87640

1280 DATA74DAF6DA74,70F80A1C0A

1290 DATA04CA32C20C,087C7E10F0

1300 DATA303AFEFC3A,167EBE7E16

1310 DATA00183C7060,D0207E20D0,60703C1800

1320 DATAFEF6F6CEFE,FEFEDE90DE,E0AEA8AEA0,A0B0DE90DE

1330 'ｴﾝﾃﾞｨﾝｸﾞ ﾒｯｾ-ｼﾞ

1340 DATAｴﾈﾃﾍ#ﾃBﾆAｿｩ#ﾃｸｿﾃ1,ｿｹｿ/ﾕﾅﾑBｶﾍ#ﾇﾕﾚﾝﾈｵ1

1350 DATAｿﾞﾍ#ﾑｶｹｵｿﾆｵｻ1,ｾｵｽBﾉ#ｴﾈﾃﾍ#ｵﾌｲﾃ1

1360 DATAﾃBﾝﾖｹB#ｿｴﾟﾁﾌ#ｶﾄﾉ#ｿﾋﾒﾀﾙｶﾉ111ﾇ1,ILQ1

1370 'ﾒｲﾛ ｺｳﾁｸ

1380 ON G GOTO 1390,1410,1430,1450

1390 X=Z-1:GOSUB 40:P1=AA:X=Z-2:GOSUB 40:P2=AA:X=Z-10:GOSUB 40:P3=AA

1400 X=Z-11:GOSUB 40:P4=AA:X=Z+10:GOSUB 40:P5=AA:X=Z+9:GOSUB 40:P6=AA:GOTO 220

1410 X=Z-10:GOSUB 40:P1=AA:X=Z-20:GOSUB 40:P2=AA:X=Z +1:GOSUB 40:P3=AA

1420 X=Z-9:GOSUB 40:P4=AA:X=Z-1:GOSUB 40:P5=AA:X=Z-11:GOSUB 40:P6=AA:GOTO 220

1430 X=Z+1:GOSUB 40:P1=AA:X=Z+2:GOSUB 40:P2=AA:X=Z+10:GOSUB 40:P3=AA

1440 X=Z+11:GOSUB 40:P4=AA:X=Z-10:GOSUB 40:P5=AA:X=Z-9:GOSUB 40:P6=AA:GOTO 220

1450 X=Z+10:GOSUB 40:P1=AA:X=Z+20:GOSUB 40:P2=AA:X=Z-1:GOSUB 40:P3=AA

1460 X=Z+9:GOSUB 40:P4=AA:X=Z+1:GOSUB 40:P5=AA:X=Z+11:GOSUB 40:P6=AA:GOTO 220

タグ ：

#FX-860P

#CASIO

#ゲーム

#プログラム

#RPG

Ray_Arms_readme

========================================================
【  ソフト名   】 Ray_Arms
【 バージョン  】 version 1.0
【 ソフト種別  】 フリーウェア/シューティング風アクション
【  制作者名   】 よなぷー
【  ファイル名 】 Ray_Arms_ver10.txt
【   対応PC 　 】 FX-860P シリーズ
【   連絡先　  】 [e-mail]
【    転載  　 】 下記参照
【　最終更新   】 2024年11月16日
========================================================

▲◆■　概要　■◆▲
　PB-100 で作った拙作『RAY ARMS』を FX-860P シリーズに移植してみました。縦画面のシューティング風アクションゲームです。


▲◆■　著作権・免責事項　■◆▲
　「Ray_Arms」はフリーソフトです。このソフト（プログラム及び関連ドキュメントを含める）の著作権は、作者であるよなぷーに帰属します。
　ソフト、及び付属テキストは、著作権法および著作権に関する条約をはじめ、その他の無体財産権に関する法律ならびに条約によって保護されています。
　作者に認められている場合を除き、このソフトを第三者に有償で提供することはこれらに違反することになりますのでご注意ください。
　ソフトを使用したことにより生じたいかなる障害、損害において、作者は一切責任を負わないものとします。各自の責任において使用してください。
　また、作者はバグが発見された場合においても、その修正、バージョンアップの義務を負わないものとします。


▲◆■　このソフトの配布、転載に関して　■◆▲
　このプログラム・関連ドキュメントの利益を伴わない再配布、または転載等は基本的に自由とします。雑誌付録への収録なども構いません。その際作者への連絡を必要としません。
　※一切のデータはオリジナルの場合に限ります。


▲◆■　入力方法　■◆▲
　全部で3496バイトあります。普通に本体で入力するか、パソコン経由でプログラムを送信してください。
　私の環境は、
・Windows 7 ノートパソコン
・BOOTH の『ac-shop』さんで購入した『CASIO FX-860Pvc 用 USB シリアル変換モジュール（FA-6 相当 IF 版）』
・USB 2.0 ケーブル【A】-【miniB】
・Windows ドライバーに WCH 製の CH340C
・通信ソフトに『PB-1000 Data Communicator32』（『JUN AMANO'S HOMEPAGE』さんより入手）
といった感じです。

●私の送信方法
　まずドライバーと通信ソフトをダウンロードして、あらかじめパソコンに入れておきます。
　次にポケコンへ USB シリアル変換モジュールを接続し、USB ケーブルで繋いで、パソコンの USB 端子にセットします。パソコンにドライバーが入っていれば、初回はそれのインストールが行なわれます。
　続いてポケコンを［ＭＯＤＥ］［１］で BASIC モードにします。そのうえで通信ソフトを立ち上げ、そこに書かれている『PB-1000 Settings:』の後の文字列をポケコンに入力します。たとえば、そのままの設定なら『LOAD"COM0:6,E,8,1,N,N,N,B,N"』となります。
　最後にポケコンのその命令を実行してから、『PB-1000 Data Communicator32』で『Send』を押してテキストファイルを選べば、パソコンからポケコンへプログラムが送信されます。
　逆にポケコンからパソコンへプログラムを送りたい（セーブしたい）なら、『Receive』を押してパソコン側の準備を整えてから、ポケコンで『SAVE"COM0:6,E,8,1,N,N,N,B,N"』を実行します。
　エラーが出てしまう場合は、『Parity』を『None』にしたり『Odd』にしたりしてみてください（私の場合はそれでうまくいきました）。そのときは『SAVE』や『LOAD』の文字列の『E』も変化しますのでご注意を。


▲◆■　物語　■◆▲
　あなたは凄腕のパイロットだ。今日も大宇宙を舞台に、異次元から現れたエイリアンと戦うのだった。


▲◆■　遊び方　■◆▲

　CAL モードで［ＳＨＩＦＴ］［（入力したプログラムエリア）］と入力するとゲーム開始です。初めて遊ぶときや記録を消去したくなった場合は［９］を、続きを遊ぶ場合はそのままで［ＥＸＥ］してください。

　ゲーム画面は左端の５桁２行の範囲となります。上段からザコ敵が降下してきますので、下段の自機（「＿」）を［Ｑ］［Ｗ］で左右に動かし、［／］で狙い撃ってください。
　ザコを１０機倒すと、上段にボス敵が現れます。ボスの攻撃（「↓」）をかわしつつ、２０発撃ち込むと倒すことができます。なお、ボス出現中のザコ敵はただの弾丸となり、破壊できません。
　ザコやボスに攻撃を受けると、タイムが８増加してしまいます。
　全部で６面あり、すべての敵を倒すとゲームクリアです。かかったタイムにより、上位３名まで名前入力ができます。


▲◆■　変数表　■◆▲
Ａ　　自機左右位置　　Ｎ　　１位タイム
Ｂ　　汎用            Ｏ　　―――
Ｃ　　敵移動方向      Ｐ＄（０）～（２）　”ｏ””○””゜”
Ｄ　　ステージ数      Ｑ＄　”↓”
Ｅ　　ボス用          Ｒ　　―――
Ｆ　　２位タイム      Ｓ＄　ボス姿
Ｇ　　時間稼ぎ等      Ｔ　　―――
Ｈ　　３位タイム      Ｕ＄　３位タイム記録者名
Ｉ　　―――          Ｖ　　―――
Ｊ　　敵左右位置      Ｗ＄　２位タイム記録者名
Ｋ　　敵縦位置        Ｘ　　ザコ／ボス／クリアチェック
Ｌ　　敵効果パターン  Ｙ＄　１位タイム記録者名
Ｍ　　タイム          Ｚ　　ボス用カウンタ


▲◆■　開発後記　■◆▲
　PB-100 では一桁画面の関係上分割表示でしたが、FX-860P は二桁ありますので、本来の姿を再現することができました。ぜひプレイして、ポケコン仲間と競い合いましょう。

　１面……ザコ＝まっすぐか斜めに降下してきます。追いかけて撃墜しましょう。
　　　　　ボス＝真ん中にときおりレーザーを放ってくるだけなので、楽勝でしょう。

　２面……ザコ＝ランダムに移動します。追いかけるのがちょっと大変かもしれません。
　　　　　ボス＝左右２門からレーザーを撃ってきます。真ん中に陣取りましょう。

　３面……ザコ＝ジグザグかまっすぐか、どちらかで降下してきます。
　　　　　ボス＝前触れの後、３マスのレーザーを放ってきます。かわしましょう。

　４面……ザコ＝下段で急降下してきます。範囲を見極めて応戦しましょう。
　　　　　ボス＝レーザーを順繰りに撃ってきます。一番大変かもしれません。

　５面……ザコ＝接地時に左右に広がります。それさえ気をつければ楽勝！？
　　　　　ボス＝マーカー（「□」）をつけて狙い撃ちしてきます。かわしましょう。

　６面……ザコ＝中央で撃っていれば倒せるでしょう。
　　　　　ボス＝３マスのレーザーをかわせば楽勝です。